Как отправить календарь нескольким получателям индивидуально в Outlook?

Обычно вы можете быстро и легко отправить календарь одному получателю с помощью функции Отправить календарь по электронной почте в Outlook. Однако если вы хотите отправить календарь в формате iCalendar нескольким контактам по отдельности, придётся делать это поочерёдно. В этой статье я расскажу о простом способе индивидуальной отправки календаря сразу нескольким получателям в Outlook.

Отправка календаря нескольким получателям по отдельности с помощью кода VBA

---

Отправка календаря нескольким получателям по отдельности с помощью кода VBA

Чтобы отправить календарь нескольким получателям по отдельности, воспользуйтесь приведённым ниже кодом VBA. Выполните следующие действия:

1. Перейдите в раздел Контакты и выберите контакты, которым хотите отправить календарь.

2. Затем нажмите и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

3. Нажмите Вставка > Модуль, скопируйте приведённый ниже код и вставьте его в открывшийся пустой модуль (см. снимок экрана):

Код VBA: Отправка календаря нескольким получателям по отдельности:

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. После вставки кода нажмите клавишу F5, чтобы запустить его. Откроется диалоговое окно Выбор папки — выберите календарь, который хотите отправить (см. снимок экрана):

5. Нажмите кнопку ОК, а затем в появившихся диалоговых окнах укажите диапазон дат, которые вы хотите использовать при отправке календаря (см. снимок экрана):

6. Затем нажмите кнопку ОК, после чего будут созданы сообщения «Новое письмо» с прикреплённым календарём, как показано на снимке экрана. Остаётся только отправить их по одному.

---

Связанные статьи:

Как отправить электронное письмо нескольким получателям по отдельности в Outlook?

Как отправить персонализированные массовые письма из списка Excel через Outlook?

Как отправить несколько черновиков одновременно в Outlook?

Как отправить электронное письмо нескольким получателям в Outlook так, чтобы они не знали друг о друге?