Как автоматически заполнить тему электронной почты именем вложения в Outlook?

Для тех, кто привык использовать имя вложения в качестве темы электронного письма в Outlook, каждый раз вручную вводить имя вложения в строке темы будет трудоемко. Как показано на рисунке ниже, если вы хотите автоматически заполнять строку темы электронной почты именем вложения при вставке вложения, вам поможет метод VBA, описанный в этом руководстве.

Автоматически заполнять тему электронной почты именем вложения с кодом VBA

Запустите следующий код VBA, чтобы автоматически заполнить тему электронной почты именем вставленного вложения в Outlook.

1. Запустите Outlook, нажмите другой + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

2. в Microsoft Visual Basic для приложений окно, дважды щелкните Проект1 (VbProject.OTM) > Объекты Microsoft Outlook > Эта сессия Outlook для открытия ThisOutlookSession (Код) редактор.

3. Затем скопируйте следующий код VBA в ThisOutlookSession (Код) редактор.

Код VBA: автозаполнение темы электронной почты именем вложения

Public WithEvents GExplorer As Explorer
'Updated by Extendoffice 20220926
Public WithEvents GInspectors As Inspectors
Public WithEvents GMail As MailItem

Private Sub Application_Startup()
  Set GExplorer = Application.ActiveExplorer
  Set GInspectors = Application.Inspectors
End Sub

Private Sub GExplorer_InlineResponse(ByVal Item As Object)
  Set GMail = Item
End Sub

Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
  Dim xItem As Object
  Set xItem = Inspector.CurrentItem
  If xItem.Class <> olMail Then Exit Sub
  Set GMail = xItem
End Sub

Private Sub GMail_AttachmentAdd(ByVal Att As Attachment)
  Dim xFileName As String
  On Error Resume Next
  If VBA.Trim(GMail.Subject) <> "" Then Exit Sub
  If MsgBox("Do you want to use the attachment name as the subject?", vbYesNo + vbInformation, "Kutools for Outlook") = vbNo Then Exit Sub
  xFileName = Att.DisplayName
  xFileName = Left$(xFileName, VBA.InStrRev(xFileName, ".") - 1)
  GMail.Subject = xFileName
End Sub

4. Теперь нужно сохранить код и перезапустить Outlook.

5. Отныне, когда вы вставляете вложение в электронное письмо, у которого еще не заполнена тема, Kutools for Outlook появится диалоговое окно с вопросом, хотите ли вы использовать имя вложения в качестве темы, нажмите Да кнопку.

Затем строка темы будет заполнена именем вставленного вложения автоматически.

Заметки: