Outlook: Как автоматически отправить письмо повторно, если нет ответа

Author Sun Last modified 2025-08-26

Когда вы отправляете электронное письмо коллеге, партнеру по сотрудничеству или кому-либо другому и вам срочно нужен ответ, вы можете настроить автоматическую повторную отправку письма, если ответ не придет до указанного времени.

Использование напоминания и VBA для настройки автоматической повторной отправки, если нет ответа

Часть 1: установка напоминания на определенное время

1. Щелкните правой кнопкой мыши письмо (из папки «Отправленные»), которое вы хотите отправить повторно, если не получили ответ, в появившемся контекстном меню выберите «Требуется дальнейшее действие» > «Добавить напоминание».

2. В появившемся диалоговом окне «Пользовательский», оставьте флажок «Напоминание» отмеченным, затем в раскрывающихся списках ниже выберите дату и время, к которым должен быть получен ответ. Вы также можете ввести дату и время непосредственно в поля. Нажмите «ОК».

Часть 2: Вставка VBA для повторной отправки писем, если нет ответа в течение указанного времени

3. Нажмите клавиши «Alt» + «F11», чтобы открыть окно «Microsoft Visual Basic for Applications».

4. Дважды щелкните «ThisOutlookSession» в панели «Проект – Project1», чтобы создать пустой скрипт, и скопируйте и вставьте следующий код VBA в этот пустой скрипт.

VBA: Повторная отправка письма, если нет ответа

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Сохраните код, затем вернитесь на главный интерфейс, нажмите «Файл» > «Параметры», и в окне «Параметры Outlook» выберите «Центр управления безопасностью» в левой панели, затем нажмите «Настройки центра управления безопасностью», чтобы открыть окно «Центр управления безопасностью». Нажмите «Настройки макросов» и убедитесь, что в правой части выбрана опция «Включить все макросы (не рекомендуется; потенциально опасный код может выполняться)». Нажмите «ОК» > «ОК».

6. Теперь, если отправленное письмо, для которого установлено напоминание, не получает ответа к указанному времени, появится диалоговое окно с напоминанием о том, хотите ли вы отправить письмо повторно для уведомления.

7. Нажмите «Да», появится окно сообщения с прикрепленным предыдущим письмом, и вы сможете отредактировать текст письма и нажать «Отправить», чтобы отправить письмо повторно.