Как сохранить категорию письма при ответе или пересылке в Outlook?

Обычно при ответе на письмо или его пересылке категория автоматически удаляется из отправляемого сообщения. Если вы хотите, чтобы категории сохранялись во всех исходящих письмах при ответе или пересылке, в этой статье описан способ решить эту задачу.

Сохранение категории при ответе или пересылке письма с помощью кода VBA

---

Сохранение категории при ответе или пересылке письма с помощью кода VBA

1. Удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

2. В окне Microsoft Visual Basic для приложений дважды щелкните элемент ThisOutlookSession на панели Project1 (VbaProject.OTM), чтобы открыть модуль, затем скопируйте и вставьте приведённый ниже код в пустой модуль.

Код VBA: Сохранение категории при ответе или пересылке письма:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Затем сохраните и закройте окно с кодом, после чего закройте и перезапустите Outlook. Теперь при ответе на письмо или его пересылке категория будет сохраняться в исходящем сообщении в папке Отправленные. См. снимок экрана: