Как отправлять письма обычным способом из папки «Отправленные» в Outlook?

Обычно, когда вы нажимаете кнопку «Ответить» в папке «Отправленные», чтобы отправить дополнительное сообщение тем же получателям, ваш собственный адрес электронной почты автоматически появляется в поле «Кому», как показано на следующем снимке экрана. Каждый раз вручную заменять его может быть неудобно. Как настроить Outlook так, чтобы он использовал адрес первоначального получателя, а не ваш?

Ответ обычным способом в папке Отправленные из Outlook с помощью функции «Ответить всем»

Ответ обычным способом в папке Отправленные из Outlook с помощью кода VBA

---

Ответ обычным способом в папке Отправленные из Outlook с помощью функции «Ответить всем»

В Outlook функция «Ответить всем» поможет решить эту проблему. Выполните следующие действия:

Когда вам нужно ответить на отправленное письмо повторно, сохранив адрес первоначального получателя, нажмите кнопку «Ответить всем», и адрес первоначального получателя появится в поле «Кому», как показано на следующем снимке экрана:

---

Ответ обычным способом в папке Отправленные из Outlook с помощью кода VBA

Иногда вы можете забыть воспользоваться функцией «Ответить всем», отвечая на отправленное сообщение. В этом случае приведённый ниже код VBA позволит вам отвечать обычным способом из папки «Отправленные», используя стандартную команду «Ответить». Выполните следующие шаги:

1. Удерживая клавиши ALT + F11, откройте окно Microsoft Visual Basic для приложений.

2. В окне Microsoft Visual Basic для приложений дважды щёлкните элемент ThisOutlookSession на панели Project1 (VbaProject.OTM), чтобы открыть модуль, затем скопируйте и вставьте приведённый ниже код в пустой модуль.

Код VBA: Ответ обычным способом в папке Отправленные из Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Сохраните код и перезапустите Outlook, чтобы изменения вступили в силу. Теперь при нажатии кнопки «Ответить» для повторной отправки письма из папки Отправленные адрес первоначального получателя будет автоматически подставляться в поле «Кому» — именно так, как вам нужно.