Как скрыть номер факса в диалоговом окне «Выбор списка имен» в Outlook?

В Outlook вы, возможно, замечали, что в списке «Выбор имен» или в Адресной книге столбец «Адрес электронной почты» отображает не только email-адреса, но и факсимильные номера — это может раздражать. В этой статье я расскажу о нескольких способах скрыть номер факса.

Скрытие номера факса в диалоговом окне «Выбор Список имен» с помощью VBA

---

Скрытие номера факса в диалоговом окне «Выбор Список имен» с помощью VBA

Если вы хотите скрыть уже существующие номера факсов в диалоговом окне «Выбор Список имен», выполните следующие действия:

1. Нажмите клавиши Alt + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

2. Выберите пункт Вставка > Модуль, чтобы добавить новый пустой модуль, затем скопируйте и вставьте приведённый ниже код в скрипт.

VBA: Скрытие существующих номеров факсов в диалоговом окне «Выбор имен»

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Нажмите клавишу F5, чтобы запустить код — теперь номера факсов будут скрыты.

Если вы хотите скрывать номера факсов в Контакт, выполните следующие действия:

1. Нажмите Alt + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

2. Дважды щёлкните по элементу ThisOutlookSession в области Проект-1, а затем скопируйте и вставьте приведённый ниже код в скрипт.

VBA: Скрытие номера факса в новых Добавить контакт

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Сохраните код и перезапустите Outlook, чтобы изменения вступили в силу.

Теперь все номера факсов для новых контактов будут автоматически скрываться в окне «Выбор имен: Контакты».