Как удалить определенные типы вложений из писем в Outlook?

Вы когда-нибудь пытались удалить вложения в нескольких выбранных письмах по типу файла в Outlook? Например, удаление всех вложенных файлов docx или png из выбранных писем. Как бы вы могли решить эту задачу в Outlook?

Удалите определенные типы вложений из писем с кодом VBA

Удалите определенные типы вложений из писем с кодом VBA

Чтобы удалить определенные типы вложений из выбранных писем, следующий код VBA может оказать вам услугу, сделайте следующее:

1. Выберите электронные письма, вложения которых вы хотите удалить, в списке рассылки.

2. Удерживайте ALT + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

3, Затем нажмите Вставить > Модули, скопируйте и вставьте приведенный ниже код в открытый пустой модуль, см. снимок экрана:

Код VBA: удалить определенные типы вложений из писем:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. А потом еще в Microsoft Visual Basic для приложений окна, нажмите Инструменты > Рекомендации , чтобы перейти к Ссылки-Project1 диалоговое окно и установите флажок Среда выполнения сценариев Microsoft из файла Доступные ссылки список, см. снимок экрана:

документ удалить прикрепить по типу 1

5. Затем нажмите OK чтобы закрыть диалоговое окно, нажмите F5 нажмите клавишу для запуска этого кода, и появится диалоговое окно, введите тип вложения, который вы хотите удалить, см. снимок экрана:

документ удалить прикрепить по типу 2