Как быстро превратить несколько встреч в задачи в Outlook?

В этой статье я покажу, как быстро и легко превратить одну или несколько встреч в задачи в Outlook.

Преобразование одной встречи в задачу с помощью перетаскивания

Преобразование нескольких встреч в задачи с помощью кода VBA

---

Преобразование одной встречи в задачу с помощью перетаскивания

Чтобы превратить встречу в задачу, просто перетащите её в папку задач. Выполните следующие действия:

1. В окне «Календарь» выберите встречу, которую нужно преобразовать в задачу, и перетащите её на значок «Задачи» в нижней части панели навигации, как показано на следующем снимке экрана:

2. Затем откроется новое окно «Задача». Нажмите «Сохранить и закрыть», чтобы сохранить эту встречу в виде задачи.

---

Преобразование нескольких встреч в задачи с помощью кода VBA

Если вам нужно преобразовать несколько встреч в задачи, приведённый ниже код VBA упростит эту задачу. Выполните следующие действия:

1. Удерживая клавиши «Alt + F11», откройте окно Microsoft Visual Basic для приложений.

2. Выберите «Вставка» > «Модуль» и вставьте приведённый ниже код в открывшийся пустой модуль:

Код VBA: Преобразование нескольких встреч в задачи

Sub ConvertAppointmentsToTasks()
Dim xItemCollection As VBA.Collection
Dim xActiveWindow As Object
Dim xItem As Object
Dim xSelection As Outlook.Selection
Dim xTaskFolder As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xTaskItem As Outlook.TaskItem
On Error Resume Next
Set xItemCollection = New VBA.Collection
Set xActiveWindow = Outlook.Application.ActiveWindow
If TypeOf xActiveWindow Is Inspector Then
    Set xItem = xActiveWindow.CurrentItem
    If xItem.Class = olAppointment Then xItemCollection.Add xItem
Else
    Set xSelection = xActiveWindow.Selection
    If xSelection Is Nothing Then Exit Sub
    For Each xItem In xSelection
        If xItem.Class = olAppointment Then xItemCollection.Add xItem
    Next
End If
Set xTaskFolder = Application.Session.PickFolder
If xTaskFolder Is Nothing Then Exit Sub
For Each xAppointmentItem In xItemCollection
    Set xTaskItem = xTaskFolder.Items.Add(olTaskItem)
    With xTaskItem
        .StartDate = Format(xAppointmentItem.Start, "Short Date")
        .DueDate = Format(xAppointmentItem.End, "Short Date")
        .Subject = xAppointmentItem.Subject & " (From Appt)"
        .Categories = xAppointmentItem.Categories
        .Body = xAppointmentItem.Body
        .Save
        .Display
    End With
Next
End Sub

3. Выделите встречи, которые нужно преобразовать в задачи, и нажмите кнопку «Выполнить макрос», чтобы запустить код.

4. Появится диалоговое окно «Выбор папки» — выберите папку «Задачи», в которую хотите сохранить преобразованные элементы.

5. Нажмите кнопку «ОК» — все выбранные встречи будут созданы как задачи. Затем последовательно нажмите «Сохранить и закрыть» в окне «Задача».

6. Теперь вы можете перейти в папку «Задачи» — все выбранные встречи сохранены как задачи.