Как экспортировать и распечатать список всех папок и подпапок в Outlook?

Как правило, для просмотра списка всех папок в области навигации Outlook достаточно нажать сочетание клавиш «Ctrl» + «6». Однако напрямую распечатать этот список невозможно. В данной статье представлены два сценария VBA, позволяющие экспортировать и распечатать список всех папок Outlook вместе с их подпапками.

• Экспорт и печать списка всех папок Outlook и их подпапок в Новое письмо
• Экспорт и печать списка всех папок Outlook и их подпапок в Блокноте

---

Экспорт и печать списка всех папок Outlook и их подпапок в Новое письмо

Этот метод описывает сценарий VBA, который экспортирует список всех папок и их подпапок указанной учётной записи электронной почты в новое письмо Outlook — после этого вы сможете легко распечатать список папок.

1. Нажмите «Alt» + «F11», чтобы открыть окно Microsoft Visual Basic for Applications.

2. Выберите «Вставка» > «Модуль» и вставьте приведённый ниже код VBA в новое окно модуля.

VBA: Экспорт списка папок и подпапок в Новое письмо в Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Нажмите «F5», чтобы запустить сценарий VBA.

4. В появившемся диалоговом окне «Выбор папки» выберите учётную запись электронной почты, список папок которой вы хотите распечатать, и нажмите «ОК».

5. Список папок выбранной учётной записи будет скопирован в новое письмо, как показано ниже. Чтобы распечатать список папок, выберите «Файл» > «Печать».

6. После печати закройте окно нового письма, не сохраняя изменения.

---

Экспорт и печать списка всех папок Outlook и их подпапок в Блокноте

Этот метод описывает сценарий VBA, который экспортирует список всех папок и их подпапок указанной учётной записи электронной почты из Outlook в Блокнот, после чего вы сможете легко распечатать этот список.

1. Нажмите «Alt» + «F11», чтобы открыть окно Microsoft Visual Basic for Applications.

2. Выберите «Вставка» > «Модуль», затем вставьте приведённый ниже код VBA в открывшееся окно модуля.

VBA: Экспорт списка всех папок Outlook и подпапок из Outlook в Блокнот

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Нажмите «F5», чтобы запустить сценарий VBA. В открывшемся диалоговом окне «Выбор папки» выберите учётную запись электронной почты, список папок которой вы хотите экспортировать и распечатать, затем нажмите «ОК».

4. Появится диалоговое окно «Структура дерева папок». Нажмите «Да», если нужно включить отступы дерева, или «Нет» — если нет.

Теперь на рабочем столе создаётся и сохраняется Текстовый файл с именем «Outlook-Folders», как показано ниже:

5. Дважды щелкните, чтобы открыть новый текстовый файл, затем выберите «Файл» > «Печать», чтобы распечатать экспортированный список папок Outlook.

Связанные статьи

Отображение или скрытие списка папок в Outlook