Как подсчитать количество страниц в PDF-файлах с помощью Excel?

Если у вас есть несколько PDF-файлов в папке и вам нужно перечислить их имена вместе с количеством страниц в Excel, это можно легко сделать с помощью простого макроса VBA. В этом руководстве мы проведем вас через шаги для быстрого извлечения и отображения имен PDF-файлов и соответствующих номеров страниц на листе Excel.

Отображение имен PDF-файлов и номеров страниц в Excel с помощью VBA

Отображение имен PDF-файлов и номеров страниц в Excel с помощью VBA

Следующий код VBA может помочь вам отобразить все имена PDF-файлов и их номера страниц на листе. Пожалуйста, следуйте этим шагам:

1. Откройте лист, где вы хотите получить PDF-файлы и номера страниц.

2. Удерживайте клавиши "ALT" + "F11", чтобы открыть окно "Microsoft Visual Basic for Applications".

3. Нажмите "Вставить" → "Модуль" и вставьте следующий макрос в окно "Модуль".

Код VBA: Перечислить все имена PDF-файлов и номера страниц на листе:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. После вставки кода нажмите клавишу "F5", чтобы запустить этот код, появится окно "Обзор", пожалуйста, выберите папку, содержащую PDF-файлы, которые вы хотите перечислить и подсчитать количество страниц, см. скриншот:

5. Затем нажмите кнопку "OK", и все имена PDF-файлов и номера страниц будут перечислены в текущем листе, см. скриншот: