Разделение текстовой строки по определённому символу в ячейке Excel

В этом руководстве объясняется, как с помощью формулы в Excel разделить текстовую строку по определённому символу на отдельные столбцы.

Как разделить текстовую строку в ячейке Excel по определённому символу?

Предположим, у вас есть список текстовых строк в столбце B, как показано на рисунке ниже, и вы хотите разделить текст по символу «-» и вывести результат в три отдельных столбца. В этом случае приведённые ниже формулы помогут вам решить задачу.

Универсальные формулы

Универсальная формула для разделения левого фрагмента текста

=LEFT(text_string,FIND("Char", text_string)-1)

Универсальная формула для разделения среднего фрагмента текста

=MID(text_string, FIND("Char", text_string) + 1, FIND("Char", text_string,FIND("Char", text_string)+1) - FIND("Char", text_string) - 1)

Универсальная формула для разделения правого фрагмента текста

=RIGHT(text_string,LEN(text_string) - FIND("Char", text_string, FIND("Char", text_string) + 1))

Аргументы приведённых выше формул

Как использовать эти формулы?

Сначала разделите первую часть текстовой строки по определённому символу

1. Выберите пустую ячейку для отображения результата — в данном примере это ячейка C3.

2. Введите в неё приведённую ниже формулу и нажмите клавишу Enter. Затем протяните ячейку с формулой ЛЕВСИМВ до конца, чтобы применить её ко всем остальным ячейкам.

=LEFT(B3,FIND("-",B3)-1)

Затем разделите среднюю часть текстовой строки по определённому символу

1. Выберите пустую ячейку, например D3, чтобы вывести результат.

2. Введите в неё приведённую ниже формулу и нажмите клавишу Enter. Выделите ячейку с результатом и протяните маркер заполнения вниз, чтобы применить формулу к остальным ячейкам.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

Наконец, разделите последнюю часть текстовой строки по определённому символу

1. Выберите пустую ячейку (например, E3) для вывода результата.

2. Введите в неё приведённую ниже формулу и нажмите клавишу Введите. Выделите ячейку с результатом и протяните маркер заполнения вниз, чтобы применить формулу к другим ячейкам.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

Теперь текстовая строка в каждой ячейке столбца B разделена на три части.

Совет: если вам нужно разделить текстовую строку на две части по определённому символу, то после выделения первой части с помощью приведённой выше формулы ЛЕВСИМВ воспользуйтесь формулой ПРАВСИМВ ниже, чтобы извлечь вторую часть, как показано на рисунке.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

Как работают эти формулы?

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)Функция НАЙТИ возвращает начальную позицию символа «-» в текстовой строке KTE-Jan-359 — результат равен 4.
• LEFT(B3,4-1): функция ЛЕВСИМВ извлекает 3 символа (4–1=3) с начала текстовой строки KTE-Jan-359. В данном случае результат — KTE.
  Примечание: поскольку первый символ «-» находится на 4-й позиции текстовой строки, из результата нужно вычесть 1, чтобы исключить его из извлечения.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: функция НАЙТИ возвращает начальную позицию символа «-» в текстовой строке KTE-Jan-359. В данном случае результат — 4.
  Примечание: поскольку первый символ «-» находится на 4-й позиции текстовой строки, к значению 4 необходимо прибавить 1, чтобы извлечь текст после него. В итоге получаем 4 + 1 = 5.
• FIND("-",B3,FIND("-",B3)+1)Здесь показан пример: НАЙТИ("-";"KTE-Jan-359";4+1) — функция НАЙТИ определяет позицию символа «-», начиная с 5-го символа в строке «KTE-Jan-359», и возвращает результат 8.
• MID(B3, 5, 8 - 4 - 1)Функция ПСТР извлекает 3 символа, начиная с 5-го символа в текстовой строке «KTE-Jan-359». Результат — «Jan».

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)Функция ДЛСТР вычисляет общую длину текстовой строки «KTE-Jan-359» и возвращает результат 11.
• FIND("-",B3,FIND("-",B3)+1)Функция НАЙТИ определяет позицию символа «-», начиная с 5-го символа в строке KTE-Jan-359, и возвращает результат 8.
• RIGHT(B3,11 - 8))Функция ПРАВСИМВ извлекает 3 символа (11 − 8) с правого конца строки «KTE-Jan-359». Результат — 359.

Связанные функции

Связанные формулы