Разделение размеров на отдельные длину, высоту и ширину

В этой статье рассказывается, как разделить размеры в ячейке на три отдельные части: длину, высоту и ширину.

Как разделить размеры на три части?

Чтобы разделить размеры на отдельные значения длины, высоты и ширины, нужно использовать три разные формулы — каждую отдельно.

Общая формула для извлечения первого размера

=LEFT(text,FIND("char",text)-1)

Общая формула для извлечения второго размера

=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))

Общая формула для извлечения третьего размера

=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))

Аргументы приведённых выше формул

Как использовать эти формулы?

Сначала нужно определить первый размер.

1. Выберите пустую ячейку, чтобы вывести первый размер.

2. Введите в неё приведённую ниже формулу и нажмите клавишу EnterВыделите ячейку с результатом и перетащите маркер заполнения, чтобы применить формулу к другим ячейкам по мере необходимости.

=LEFT(B5,FIND("x",B5)-1)

Затем разделим второй размер следующим образом.

1. Выберите пустую ячейку, чтобы вывести второй размер.

2. Введите в неё приведённую ниже формулу и нажмите клавишу Enter. Выделите ячейку с результатом и перетащите маркер заполнения, чтобы применить формулу к другим ячейкам по мере необходимости.

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

Наконец, получим последний размер

1. Выберите пустую ячейку, чтобы отобразить последний размер.

2. Введите в неё приведённую ниже формулу и нажмите клавишу EnterВыделите ячейку с результатом и перетащите маркер заполнения, чтобы при необходимости применить формулу к другим ячейкам.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

Как работают эти формулы?

=LEFT(B5,FIND("x",B5)-1)

1. FIND("x",B5)-1: Функция НАЙТИ определяет позицию первого вхождения символа «x» в ячейке B5. Чтобы получить длину первой части размера (без учёта «x»), из этой позиции вычитается 1. В результате получаем 4–1=3.
2. LEFT(B5,3): Функция ЛЕВСИМВ извлекает первые 3 символа с левой стороны ячейки B5 и возвращает результат «100».

=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))

1. FIND("x",B5)+1Функция НАЙТИ определяет позицию первого символа «x» в ячейке B5. Поскольку второй размер начинается сразу после этого символа «x», к найденной позиции нужно добавить 1. В результате получаем: 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): Функция ПОДСТАВИТЬ заменяет второй символ «x» в ячейке B5 на «@» и возвращает результат в виде 100x50@300;
• FIND("@",100x50@300): В этом примере функция НАЙТИ определяет позицию символа «@» в тексте 100x50@300 и возвращает результат — 7.

3. (НАЙТИ("x";B5)+1): Как указано на шаге 1, функция НАЙТИ определяет позицию первого символа «x» в ячейке B5 и прибавляет 1, чтобы получить результат 5.
4. ПСТР(B5;5;7-5): Функция ПСТР извлекает два символа (7–5=2), начиная с пятого символа текста в ячейке B5, и возвращает окончательный результат — 50.

=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))

1. LEN(B5): Функция ДЛСТР вычисляет общее количество Фильтр по длине строки в ячейке B5 и возвращает результат как 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):

• SUBSTITUTE(B5,"x","@",2): Функция ПОДСТАВИТЬ заменяет второй символ «x» в ячейке B5 на «@» и возвращает результат в виде 100x50@300;
• FIND("@",100x50@300): В данном случае функция НАЙТИ определяет позицию символа «@» в тексте 100x50@300 и возвращает результат как 7.

3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10–7) Общая длина текстовой строки в ячейке B5 минус первые 7 символов даёт результат 3.
4. RIGHT(B5,3): Затем функция ПРАВСИМВ извлекает 3 символа с правого края ячейки B5 и возвращает третий размер — 300.

Связанные функции

Связанные формулы