Как удалить все категории из Outlook?

Предположим, в вашей Outlook к цветовой категории применено множество элементов. Если вам нужно удалить все эти категории из элементов, как можно быстро и легко справиться с этой задачей в Outlook?

Очистить все категории из определенной папки с помощью функции Очистить все категории

Очистить все категории из определенной учетной записи с кодом VBA

---

Очистить все категории из определенной папки с помощью функции Очистить все категории

Если вам просто нужно очистить категории в определенной папке, сделайте следующее:

1. Щелкните папку, из которой нужно удалить цветовые категории, а затем нажмите Ctrl + чтобы выбрать все элементы.

2. Затем щелкните правой кнопкой мыши и выберите классифицировать > Очистить все категории из контекстного меню см. снимок экрана:

3. И затем все цветовые категории в этой конкретной папке были очищены сразу.

---

Очистить все категории из определенной учетной записи с кодом VBA

Чтобы удалить все категории из всех элементов, таких как электронные письма, задачи, контакты, заметки и т. Д. Из учетной записи, приведенный ниже код VBA может оказать вам услугу:

1. Щелкните адрес электронной почты учетной записи, из которого вы хотите удалить все категории, затем удерживайте ALT + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

2. Нажмите Вставить > Модули, и вставьте следующий макрос в Модули Окно.

Код VBA: очистить все категории из определенной учетной записи:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3, Затем нажмите F5 нажмите клавишу, чтобы запустить его, а затем появится окно с подсказкой, чтобы напомнить вам, что все категории из выбранной учетной записи были очищены, см. снимок экрана: