Как автоматически перемещать отправленные приглашения на встречи в определённую папку в Outlook?

Обычно после отправки писем или приглашений на встречи оба типа сообщений помещаются в папку Отправленные. В результате папка Отправленные становится крайне перегруженной и неудобной для использования. В этой статье я расскажу о способе автоматического перемещения отправленных встреч в другую папку сразу после их отправки.

Автоматическое перемещение отправленных встреч в определённую папку с помощью кода VBA

---

Автоматическое перемещение отправленных встреч в определённую папку с помощью кода VBA

Чтобы автоматически перемещать все отправленные приглашения на встречи в другую папку, воспользуйтесь приведённым ниже кодом. Выполните следующие действия:

1. Удерживая клавиши ALT + F11, откройте окно Microsoft Visual Basic for Applications.

2. В окне Microsoft Visual Basic for Applications дважды щёлкните по элементу ThisOutlookSession на панели Project1 (VbaProject.OTM), чтобы открыть модуль, затем скопируйте и вставьте приведённый ниже код в пустой модуль.

Код VBA: автоматическое перемещение отправленных встреч в определённую папку

Private WithEvents GExplorer As Outlook.Explorer
Public WithEvents GSentFolder As Outlook.Folder
Public WithEvents GSentItems As Outlook.Items
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
Dim xFolder As Folder, xRootFolder As Folder
Dim xRootFldName As String
Dim xPos As Integer
    On Error Resume Next
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    xPos = VBA.InStr(3, xFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = VBA.Mid(xFolder.FolderPath, 3, Len(xFolder.FolderPath) - 2)
    End If
    Set xRootFolder = Outlook.Application.Session.Folders(xRootFldName)
    Set GSentFolder = xRootFolder.Folders("Sent Items")
    Set GSentItems = GSentFolder.Items
End Sub
Private Sub GSentItems_ItemAdd(ByVal Item As Object)
    Dim xMeetingItem As Outlook.MeetingItem
    Dim xTargetFolder As Outlook.Folder
    On Error Resume Next
    If Item.Class <> olMeetingRequest Then Exit Sub
    Set xMeetingItem = Item
    Set xTargetFolder = GSentFolder.Folders("Meetings")
    If xTargetFolder Is Nothing Then
        Set xTargetFolder = GSentFolder.Folders.Add("Meetings")
    End If
    xMeetingItem.Move xTargetFolder
End Sub

3. Затем сохраните и закройте окно с кодом. Теперь, когда приглашение на встречу будет отправлено, оно автоматически переместится в папку Meetings, расположенную в папке Отправленные. См. снимок экрана: