Как распечатать задачи по категориям в Outlook?

Допустим, в ваших задачах Outlook заданы разные цветовые категории, и вы хотите распечатать списки задач по категориям — каждый на отдельной странице. Как это сделать в Outlook?

Распечатка задач по категориям на отдельных страницах вручную, по одной

Распечатка задач по категориям на отдельных страницах с помощью кода VBA

---

Распечатка задач по категориям на отдельных страницах вручную, по одной

В Outlook вы можете вручную распечатать задачи по категориям — каждую категорию на отдельной странице, одну за другой. Выполните следующие действия:

1. Запустите Outlook, перейдите на панель «Задачи», выберите папку с задачами, которую нужно распечатать, и нажмите Ctrl + E, чтобы активировать поле Поиск. Затем на вкладке Поиск нажмите значок По категориям и выберите нужную цветовую категорию для печати (см. снимок экрана):

2. После этого все задачи с указанной цветовой категорией отобразятся сразу (см. снимок экрана):

3. Затем последовательно нажмите Файл > Печать, чтобы распечатать этот список задач, как показано на следующем снимке экрана:

4. Повторите описанные выше действия, чтобы вручную распечатать списки задач с другими цветовыми категориями по очереди.

---

Распечатка задач по категориям на отдельных страницах с помощью кода VBA

Ниже приведён код VBA, который позволяет за один раз распечатать задачи по категориям на отдельных страницах. Выполните следующие шаги:

1. Перейдите в панель Задачи и выберите папку с задачами, которую нужно распечатать.

2. Затем нажмите и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

3. Далее выберите Вставка > Модуль и скопируйте приведённый ниже код в открывшийся пустой модуль:

Код VBA: Распечатка задач по категориям на отдельных страницах:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Затем в окне Сервис > Ссылки среды Microsoft Visual Basic для приложений в появившемся диалоговом окне Ссылки – Project1 установите флажки напротив пунктов Microsoft Excel Object Library и Среда выполнения Microsoft Scripting в списке Доступные ссылки (см. снимок экрана):

5. Нажмите кнопку ОК, а затем — клавишу F5, чтобы запустить код. После завершения выполнения кода списки задач с разными категориями будут распечатаны на отдельных страницах.