Как автоматически помечать письма флагом в Outlook на основе определённого вложения?

При получении писем с определёнными важными вложениями часто возникает необходимость пометить их флагом, чтобы в будущем быстро и легко найти для дальнейшей работы. В этой статье я расскажу о простом способе автоматической установки флага на письма, вложения которых имеют заданные имена.

Автоматическая установка флага на письма на основе определённого вложения с помощью кода VBA

---

Автоматическая установка флага на письма на основе определённого вложения с помощью кода VBA

Чтобы автоматически помечать флагом письма, содержащие определённое вложение, примените следующий код VBA:

1. Запустите Outlook и нажмите клавиши «Alt + F11», чтобы открыть окно Microsoft Visual Basic для приложений.

2. В окне «Microsoft Visual Basic для приложений» дважды щёлкните элемент «ThisOutlookSession» на панели «Project1 (VbaProject.OTM)», чтобы открыть модуль, затем скопируйте и вставьте приведённый ниже код в открывшееся пустое окно модуля.

Код VBA: автоматическая установка флага на письма на основе определённого вложения:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Примечание. В приведённом выше коде вы можете изменить расширение файла и имя вложения в соответствии со своими потребностями.

3. Сохраните код и перезапустите Outlook, чтобы изменения вступили в силу. Теперь при получении писем, имена вложений которых содержат указанный текст, Outlook будет автоматически помечать такие сообщения флагом для последующей работы (см. снимок экрана):