Как экспортировать структуру папок из Outlook в Excel?

В этой статье я покажу, как экспортировать структуру папок учётной записи из Outlook в файл Excel. Следуйте приведённым ниже инструкциям, чтобы получить нужный результат.

Экспорт Структура папок учетной записи из Outlook в Excel с помощью кода VBA

---

Экспорт Структура папок учетной записи из Outlook в Excel с помощью кода VBA

Приведённый ниже код VBA поможет вам в этом. Следуйте инструкциям:

1.Запустите Excel и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic для приложений.

2. Нажмите Вставка > Модуль и вставьте приведённый ниже код в окно Модуля.

Код VBA: экспорт Структура папок учетной записи из Outlook в Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3. Оставаясь в окне Microsoft Visual Basic для приложений, выберите Сервис > Ссылки, чтобы открыть диалоговое окно Ссылки – Project1, и установите флажок рядом с пунктом Microsoft Excel Object Library в списке Доступные ссылки (см. скриншот):

4. Затем нажмите кнопку ОК и клавишу F5, чтобы запустить код. Появится диалоговое окно Выбор папки. Выберите учётную запись электронной почты — именно структуру папок этой учётной записи вы хотите экспортировать. См. скриншот:

5. После этого нажмите кнопку ОК, и появится окно Сохранение файла, в котором укажите путь и имя файла для экспортируемых данных (см. скриншот):

6. Наконец, нажмите кнопку Сохранить, после чего откройте указанную рабочую книгу Excel, чтобы просмотреть экспортированную структуру папок (см. скриншот):