Как настроить разные подписи для ответов и пересылок в Outlook?

Обычно в Outlook можно задать разные подписи для разных учётных записей, но пробовали ли вы когда-нибудь использовать разные подписи для ответов и пересылок? То есть чтобы при ответе на письмо автоматически вставлялась подпись 1, а при пересылке — подпись 2. Как реализовать такую настройку в Outlook?

Настройка разных подписей для ответов и пересылок с помощью кода VBA

---

Настройка разных подписей для ответов и пересылок с помощью кода VBA

Приведённый ниже код VBA позволит вам настроить разные подписи для ответов и пересылок. Выполните следующие действия по порядку:

1. Удерживая нажатыми клавиши ALT + F11, откройте окно Microsoft Visual Basic for Applications.

2. Затем нажмите Вставка > Модуль и скопируйте приведённый ниже код в открывшийся пустой модуль (см. снимок экрана):

Код VBA: Настройка разных подписей для ответов и пересылок:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

Примечание: В приведённом выше коде Signature1 и Signature2 — это имена двух подписей, которые вы хотите использовать для ответов и пересылок соответственно. Замените их на нужные вам имена.

3. Не закрывая окно Microsoft Visual Basic for Applications, нажмите Сервис > Ссылки, чтобы открыть диалоговое окно Ссылки – Project1, и установите флажок напротив пункта Microsoft Scripting Runtime в списке Доступные ссылки (см. снимок экрана):

4. Затем нажмите ОК, чтобы закрыть диалоговое окно. Начиная с этого момента, при ответе на письмо автоматически будет вставляться Signature1 (см. снимок экрана):

А при пересылке сообщения будет вставляться Signature2, как показано на следующем снимке экрана: