Как выполнить поиск и замену текста в темах сообщений или задач в Outlook?

В Outlook, если вам нужно заменить текст тем сразу нескольких сообщений или задач на указанный вами текст, вы, конечно, можете редактировать их по одному — но существует ли более быстрый способ выполнить эту операцию для всех нужных элементов сразу?

Поиск и замена текст темы в нескольких сообщениях с помощью кода VBA

Поиск и замена текст темы в нескольких задачах с помощью кода VBA

---

Поиск и замена текст темы в нескольких сообщениях с помощью кода VBA

Чтобы найти определённый текст и заменить его другим в темах сразу нескольких сообщений, воспользуйтесь приведённым ниже кодом VBA. Выполните следующие шаги:

1. Выделите сообщения, в теме которых нужно выполнить поиск и замену текста, затем нажмите клавиши «ALT + F11», чтобы открыть окно «Microsoft Visual Basic for Applications».

2. Затем выберите «Вставка» > «Модуль» и скопируйте приведённый ниже код в открывшийся пустой модуль (см. снимок экрана):

Код VBA: Поиск и замена текст темы в нескольких сообщениях:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Примечание. В приведённом выше коде: xNewSubject = Replace(.Subject, «kte», "Kutools для Excel") — «kte» представляет собой текст, который нужно найти (Старый текст), а «Kutools для Excel» — текст, на который его следует заменить (Новый текст). Измените их в соответствии с вашими задачами.

3. Затем нажмите клавишу «F5», чтобы запустить этот код. Указанный текст в темах сообщений будет заменён на новый в соответствии с вашими настройками (см. снимок экрана):

---

Поиск и замена текст темы в нескольких задачах с помощью кода VBA

Если вам нужно выполнить поиск и замену текста темы в задачах, следующий код VBA поможет вам в этом.

1. Нажмите клавиши «ALT + F11», чтобы открыть окно Microsoft Visual Basic for Applications.

2. Затем выберите «Вставка» > «Модуль» и скопируйте приведённый ниже код в открывшийся пустой модуль (см. снимок экрана):

Код VBA: Поиск и замена текст темы во всех задачах:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Затем нажмите клавишу «F5», чтобы запустить этот код. Появится диалоговое окно, в котором нужно указать текст для поиска в темах задач (см. снимок экрана):

4. Нажмите «ОК» — после этого откроется ещё одно диалоговое окно. Введите новый текст, на который нужно выполнить замену (см. снимок экрана):

5. Затем нажмите «ОК». Появится диалоговое окно с информацией о количестве изменённых тем (см. снимок экрана):

6. Нажмите «ОК», и старый текст в темах задач будет заменён на новые значения (см. снимок экрана):