Как скопировать структуру папок Outlook на рабочий стол (проводник Windows)?

Author: Kelly Last Modified: 2025-08-07

Как вы знаете, мы можем использовать функцию архивирования для копирования структуры папок в другой Outlook, но знаете ли вы, как скопировать структуру папок Outlook в определенную папку Windows, например, на рабочий стол? В этой статье будет представлен VBA-код для легкого копирования структуры папок Outlook в проводник Windows.

Копирование структуры папок Outlook на рабочий стол (проводник Windows)

Копирование структуры папок Outlook на рабочий стол (проводник Windows)

Пожалуйста, следуйте приведенным ниже шагам, чтобы скопировать структуру папок Outlook на рабочий стол или в проводник Windows.

1. На панели навигации щелкните, чтобы выделить указанную папку, структуру которой вы хотите скопировать, и нажмите клавиши "Alt" + "F11", чтобы открыть окно Microsoft Visual Basic for Applications.

the screenshot of step about copying Outlook folder structure to desktop (windows explorer) using vba 1

2. Нажмите "Сервис" → "Ссылки", чтобы открыть диалоговое окно Ссылки. Затем в диалоговом окне отметьте опцию "Microsoft Scripting Runtime" и нажмите кнопку "OK". Смотрите скриншот:

the screenshot of step about copying Outlook folder structure to desktop (windows explorer) using vba 2

3. Нажмите "Вставить" → "Модуль" и скопируйте и вставьте приведенный ниже код VBA в новое окно модуля.

VBA: Копирование структуры папок Outlook в проводник Windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Нажмите клавишу "F5" или кнопку "Выполнить", чтобы запустить этот код VBA.

5. В появившемся диалоговом окне "Обзор папок" выберите указанную папку, куда вы разместите скопированную структуру папок, и нажмите кнопку "OK". Смотрите скриншот: