Как пометить непрочитанные письма старше определенных дней как автоматически прочитанные в Outlook?

Если в папке «Входящие» есть несколько непрочитанных писем, обычно вы можете применить функцию «Пометить все как прочитанные», чтобы вручную пометить все непрочитанные письма как прочитанные. Но пытались ли вы когда-нибудь пометить непрочитанные электронные письма, которые старше определенных дней, как автоматически прочитанные в Outlook, не настраивая каждый раз вручную?

Отметить непрочитанные письма старше определенных дней как прочитанные автоматически с помощью кода VBA

Отметить непрочитанные письма старше определенных дней как прочитанные автоматически с помощью кода VBA

Чтобы автоматически отмечать все непрочитанные электронные письма старше определенных дней как прочитанные, следующий код VBA может оказать вам услугу:

1. Удерживайте ALT + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

2. В Microsoft Visual Basic для приложений окно, дважды щелкните Эта сессия Outlook из Проект1 (VbaProject.OTM) панель, чтобы открыть режим, а затем скопируйте и вставьте приведенный ниже код в пустой модуль.

Код VBA: автоматическая пометка непрочитанных писем старше определенных дней как прочитанных:

Private Sub Application_Startup()
        Call MarkOldUnreadEmailsAsRead
    End Sub
    Private Sub MarkOldUnreadEmailsAsRead()
    Dim xInboxFld As Outlook.Folder
    Dim xAccount As Account
    On Error GoTo L1
    For Each xAccount In Outlook.Application.Session.Accounts
        Set xInboxFld = xAccount.DeliveryStore.GetDefaultFolder(olFolderInbox)
        Call Processfolders(xInboxFld)
    Next xAccount
L1:     Exit Sub
    End Sub
    Private Sub Processfolders(ByVal InboxFld As Outlook.Folder)
    Dim xItems As Outlook.Items
    Dim i As Long
    Dim xSubFld As Outlook.Folder
    On Error Resume Next
    Set xItems = InboxFld.Items
    For i = 1 To xItems.Count
        If DateDiff("d", xItems(i).ReceivedTime, Now) >= 15 Then
           If xItems(i).UnRead = True Then
              xItems(i).UnRead = False
              xItems(i).Save
           End If
        End If
    Next
    If InboxFld.Folders.Count > 0 Then
       For Each xSubFld In InboxFld.Folders
           Call Processfolders(xSubFld)
       Next
    End If
End Sub

Внимание: В приведенном выше коде вы можете изменить количество дней в этом скрипте: Если DateDiff ("d", xItems (i) .ReceivedTime, Now)> = 15 Затем к вашему собственному необходимому.

3. Затем сохраните и закройте это окно кода, с тех пор каждый раз, когда вы запускаете Outlook, все непрочитанные электронные письма, которые старше заранее определенных дней, будут автоматически отмечаться как прочитанные.

Внимание: Этот код доступен только для учетной записи по умолчанию.