Как найти папку (полный путь к папке) по имени папки в Outlook?

Пожалуйста, следуйте приведенным ниже шагам, чтобы выполнить поиск папок по именам папок с помощью VBA в Outlook.

1. Нажмите клавиши «Alt» + «F11» вместе, чтобы открыть окно «Microsoft Visual Basic for Applications».

2. Нажмите «Вставить» > «Модуль», а затем вставьте следующий код VBA в новое окно Модуля.

VBA: Поиск и открытие папок по имени папки в Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Нажмите клавишу «F5» или кнопку «Выполнить», чтобы запустить этот VBA.

4. В появившемся диалоговом окне «Поиск папки» введите имя папки, по которой будете выполнять поиск, и нажмите кнопку «ОК».

Примечание: Этот VBA поддерживает подстановочный знак звездочки. Например, вы можете ввести tes*, чтобы найти все папки, чьи имена начинаются с tes.

5. Теперь появится диалоговое окно, которое покажет путь к найденной папке. Если вам нужно открыть найденную папку, нажмите кнопку «Да».

И теперь найденная папка открывается на панели навигации, как показано на скриншоте ниже:

Примечание: Если существует более одной папки с указанным именем, этот VBA может найти и открыть только одну из них.

Если у вас установлен Kutools для Outlook, вы можете использовать его функцию «Открыть папку», чтобы быстро найти все папки по определенному имени папки и легко открыть любую из найденных папок.

1. Нажмите «Kutools Plus» > «Открыть папку», чтобы включить эту функцию.

2. В диалоговом окне «Открыть папку» введите указанное имя папки в поле «Поиск», выберите папку в результатах поиска и нажмите кнопку «ОК».

Теперь указанная папка с определенным именем найдена и немедленно открыта.