Перейти к содержимому

Случайные данные в Excel: генерация случайных чисел, текстов, дат и времени в Excel

Author: Xiaoyang Last Modified: 2025-06-05

В целом, случайные данные — это последовательности чисел, текстовых строк или других символов, которые используются в статистической выборке, шифровании данных, лотереях, тестировании или обучении, а также в других областях, где необходимы непредсказуемые результаты. В этой статье мы рассмотрим различные способы генерации случайных чисел, текстовых строк, дат и времени как в стандартном Excel, так и в Excel365.

Содержание:

1. Генерация случайных чисел, текстов, дат, времени в Excel

2. Генерация случайных чисел, текстов, дат в Excel365 /2021 и более новых версиях

3. Как зафиксировать случайные результаты, чтобы они не изменялись


Генерация случайных чисел, текстов, дат, времени в Excel

В этом разделе рассматриваются различные решения для генерации чисел, текстовых строк, дат и времени на листе Excel.

1.1 Генерация случайных чисел в Excel

Чтобы сгенерировать или вставить несколько случайных чисел на листе, стандартные функции RAND или RANDBETWEEN могут значительно упростить задачу. Помимо формул, существуют также коды и простые инструменты, которые помогут вам в этом.

Функция RAND для генерации случайных чисел

Генерация случайных десятичных чисел между двумя числами

Функция RAND позволяет генерировать случайные десятичные числа между0 и1, между0 и любым другим числом или между двумя конкретными числами.

Формула Описание
=RAND() Генерирует случайные десятичные числа между0 и1.
=RAND()*N Генерирует случайные десятичные числа между0 и N.
=RAND()*(B-A)+A Генерирует случайные десятичные числа между любыми двумя указанными вами числами. (A — это нижняя граница, B — верхняя граница.)

Скопируйте нужную формулу выше и примените ее к нужному количеству ячеек — вы получите результат, как показано на скриншотах ниже:

=RAND() =RAND()*50 =RAND()*(100-50)+50
A screenshot of the result from the formula =RAND() showing random decimal numbers between 0 and 1 in Excel A screenshot of the result from the formula =RAND()*50 showing random decimal numbers between 0 and 50 in Excel A screenshot of the result from the formula =RAND()*(100-50)+50 showing random decimal numbers between 50 and 100 in Excel

Генерация случайных целых чисел между двумя числами

Чтобы сгенерировать случайные целые числа, объедините функции RAND и INT, как показано в таблице ниже:

Формула Описание
=INT(RAND()*N) Генерирует случайные целые числа между0 и N.
=INT(RAND()*(B-A)+A) Генерирует случайные целые числа между любыми двумя указанными вами числами. (A — это нижняя граница, B — верхняя граница.)

Примените нужную формулу, затем перетащите и скопируйте ее в другие ячейки по необходимости — результат будет, как показано на скриншотах ниже:

=INT(RAND()*100) =INT(RAND()*(500-200)+200)
A screenshot of the result from the formula =INT(RAND()*100) showing random integers between 0 and 100 in Excel A screenshot of the result from the formula =INT(RAND()*(500-200)+200) showing random integers between 200 and 500 in Excel

Функция RANDBETWEEN для генерации случайных чисел

В Excel есть функция RANDBETWEEN, которая также позволяет быстро и просто создавать случайные числа.

Генерация случайных целых чисел между двумя числами

=RANDBETWEEN(bottom, top)
  • bottom, top: минимальное и максимальное значения диапазона случайных чисел, который вы хотите получить.

Например, чтобы сгенерировать случайные целые числа от100 до200, примените формулу ниже в пустую ячейку, затем перетащите и скопируйте формулу в другие нужные ячейки, см. скриншот:

=RANDBETWEEN(100,200)

A screenshot of the result from the formula =RANDBETWEEN(100, 200) showing random integers between 100 and 200 in Excel

Совет: функция RANDBETWEEN также может создавать как положительные, так и отрицательные числа. Чтобы вставить случайные числа от -100 до100, просто измените значение bottom на -100, см. формулу ниже:

=RANDBETWEEN(-100,100)

A screenshot of the result from the formula =RANDBETWEEN(-100, 100) showing random integers between -100 and 100 in Excel


Генерация случайных чисел с заданным количеством знаков после запятой между двумя числами

Чтобы создать случайные числа с определенным количеством знаков после запятой, измените формулу RANDBETWEEN следующим образом:

  • Случайные числа с одним знаком после запятой: =RANDBETWEEN(bottom*10, top*10)/10
  • Случайные числа с двумя знаками после запятой: =RANDBETWEEN(bottom*100, top*100)/100
  • Случайные числа с тремя знаками после запятой: =RANDBETWEEN(bottom*1000, top*1000)/1000
  • ...

Здесь я хочу получить список случайных чисел от10 до50 с двумя знаками после запятой. Примените формулу ниже и перетащите ее в другие ячейки по необходимости, см. скриншот:

=RANDBETWEEN(10*100,50*100)/100

A screenshot of the result from the formula =RANDBETWEEN(10*100, 50*100)/100 showing random numbers with two decimal places between 10 and 50 in Excel


Пользовательская функция для генерации случайных чисел между двумя значениями

Следующая пользовательская функция также поможет сгенерировать случайные целые числа или числа с определенным количеством знаков после запятой в диапазоне листа. Выполните следующие действия:

1. Удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставка > Модуль и вставьте следующий код в окно модуля.

VBA-код: Генерация случайных чисел

Public Function RandomNumbers(Num1 As Long, Num2 As Long, Optional Decimals As Integer)
'Updateby Extendoffice
Application.Volatile
Randomize
If IsMissing(Decimals) Or Decimals = 0 Then
    RandomNumbers = Int((Num2 + 1 - Num1) * Rnd + Num1)
Else
    RandomNumbers = Round((Num2 - Num1) * Rnd + Num1, Decimals)
End If
End Function

3. Затем закройте код и вернитесь на лист, в пустой ячейке введите формулу =RandomNumbers(X,Y,Z).

Примечание: В приведенной выше формуле X — это нижний предел чисел, Y — верхний предел, а Z — количество знаков после запятой для случайных чисел. Измените их на нужные вам значения.

1.) Чтобы сгенерировать случайные целые числа от50 до200, используйте формулу:

=RandomNumbers(50,200,0)

2.) Чтобы вставить случайные числа от50 до200 с двумя знаками после запятой, примените формулу ниже:

=RandomNumbers(50,200,2)

4. В конце перетащите и скопируйте формулу в другие ячейки по необходимости — результат будет, как показано на скриншотах ниже:

A screenshot of the result from the custom VBA formula =RandomNumbers(50,200,0) showing random integers between 50 and 200 in Excel A screenshot of the result from the custom VBA formula =RandomNumbers(50,200,2) showing random numbers with two decimal places between 50 and 200 in Excel

Удобная функция для генерации случайных чисел между двумя числами

Если вам надоело запоминать и вводить формулы, рекомендую воспользоваться удобной функцией — Вставить случайные данные Kutools для Excel. С помощью этой функции вы сможете генерировать случайные целые или десятичные числа без формул.

Kutools для Excel - Наполнен более чем 300 необходимыми инструментами для Excel. Воспользуйтесь постоянно бесплатными функциями ИИ! Скачайте прямо сейчас!

1. Выделите диапазон ячеек, в которых хотите сгенерировать случайные числа, затем нажмите Kutools > Вставка > Вставить случайные данные, см. скриншот:

A screenshot of the Insert Random Data option in Kutools under the Insert tab on the Ribbon

2. В диалоговом окне Вставить случайные данные:

1.) Генерация случайных целых чисел:

На вкладке Целое число в полях От и До укажите диапазон чисел, между которыми будут сгенерированы случайные целые числа, затем нажмите ОК или Применить, чтобы получить результат, как показано на скриншоте ниже:

A screenshot of the Insert Random Data dialog box generating random whole numbers under the Integer tab

2.) Генерация случайных чисел с определенным количеством знаков после запятой:

На вкладке Десятичное число отдельно укажите два числа в полях От и До, между которыми вы хотите сгенерировать случайные десятичные числа. Затем выберите количество знаков после запятой в поле Десятичные знаки и нажмите ОК или Применить для генерации случайных чисел. См. скриншот:

A screenshot of the Insert Random Data dialog box generating random decimal numbers under the Decimal tab

Совет: Чтобы сгенерировать случайные десятичные числа без повторов, установите флажок Сгенерировать уникальные значения.


1.2 Генерация случайных чисел без повторов (уникальные случайные числа)

При использовании формул или кода для генерации случайных чисел могут появляться дубликаты. Если вы хотите создать список случайных чисел без повторов, в этом разделе показаны несколько способов решения задачи.

Генерация случайных чисел без повторов с помощью формулы массива

Например, я хочу сгенерировать случайные числа от100 до200 без повторов. Вот сложная формула массива, которая поможет вам — выполните следующие шаги:

1. Укажите нижнее и верхнее значения в двух ячейках. В этом примере я введу100 и200 в ячейки B2 и B3, см. скриншот:

A screenshot showing the input of lower and upper limits in cells B2 and B3 for generating random numbers in Excel

2. Затем скопируйте следующую формулу в пустую ячейку, например D3 (не вставляйте формулу в ячейку первой строки), и нажмите Ctrl+ Shift + Enter, чтобы получить первое число, см. скриншот:

=IFERROR(LARGE(ROW(INDIRECT($B$1&":"&$B$2))*NOT(COUNTIF($D$2:D2,ROW(INDIRECT($B$1&":"&$B$2)))),RANDBETWEEN(1,$B$2-$B$1-ROW(A1)+2)),"")

Примечание: В формуле выше B1 — нижнее значение, B2 — верхнее значение, между которыми вы хотите получить случайные числа. D2 — ячейка над формулой.

A screenshot of the initial result of the array formula for generating unique random numbers in Excel

3. Затем перетащите и скопируйте формулу в другие ячейки, чтобы сгенерировать случайные числа от100 до200:

A screenshot showing a list of unique random numbers generated between 100 and 200 using an array formula in Excel


Генерация случайных чисел без повторов с помощью VBA-кода

Если формула выше кажется вам сложной, воспользуйтесь приведенным ниже VBA-кодом — выполните следующие действия:

1. Удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставка > Модуль и вставьте следующий код в окно модуля.

VBA-код: Генерация случайных чисел без повторов

Sub Range_RandomNumber()
'Updateby Extendoffice
Dim xStrRange As String
Dim xRg, xCell, xRg1 As Range
Dim xArs As Areas
Dim xNum_Lowerbound As Integer
Dim xNum_Upperbound  As Integer
Dim xI, xJ, xS, xR As Integer
xStrRange = "A1:B20"
xNum_Lowerbound = 100
xNum_Upperbound = 200
Set xRg = Range(xStrRange)
Set xArs = xRg.Areas
xRgCount = 0
For xI = 1 To xArs.Count
    Set xCell = xArs.Item(xI)
    xRgCount = xCell.Count + xRgCount
Next xI
xS = (xNum_Upperbound - xNum_Lowerbound + 1)
If xRgCount > xS Then
    MsgBox ("Number of cells greater than the number of unique random numbers!")
    Exit Sub
End If
    xRg.Clear
For xI = 1 To xArs.Count
    Set xCell = xArs.Item(xI)
    For xJ = 1 To xCell.Count
        Set xRg1 = xCell.Item(xJ)
        xR = Int(xS * Rnd + xNum_Lowerbound)
        Do While Application.WorksheetFunction.CountIf(xRg, xR) >= 1
            xR = Int(xS * Rnd + xNum_Lowerbound)
        Loop
        xRg1.Value = xR
    Next
Next
End Sub

Примечание: В приведенном выше коде xStrRange = "A1:B20" означает, что вы хотите сгенерировать случайные числа в диапазоне A1:B20. xNum_Lowerbound = 100 и xNum_Upperbound = 200 — это нижнее и верхнее значения для генерации случайных чисел от100 до200. Измените их по своему усмотрению.

3. Затем нажмите клавишу F5 для запуска кода, и уникальные случайные числа будут вставлены в указанный диапазон.


Генерация случайных чисел без повторов с помощью мощной функции

Чтобы быстро создать несколько уникальных случайных чисел, функция Вставить случайные данные Kutools для Excel поддерживает умную опцию — Сгенерировать уникальные значения. Просто установите этот флажок, и задача будет решена легко.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек, в которых хотите сгенерировать случайные числа.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные. В появившемся диалоговом окне выполните следующие действия:

  • На вкладке Целое число в полях От и До укажите диапазон чисел, между которыми будут сгенерированы случайные числа;
  • Установите флажок Сгенерировать уникальные значения;
  • Затем нажмите ОК или Применить, чтобы получить уникальные случайные числа, как показано на скриншоте ниже.

A screenshot showing the Insert Random Data dialog box with the Unique values option checked


1.3 Генерация случайных четных или нечетных чисел в Excel

Если вы хотите сгенерировать случайные четные или нечетные числа в диапазоне ячеек, просто вложите функцию RANDBETWEEN в функцию EVEN или ODD. Общий синтаксис:

Формула Описание
=EVEN(RANDBETWEEN(bottom,top)) Генерирует случайные четные числа между двумя заданными числами.
=ODD(RANDBETWEEN(bottom,top)) Генерирует случайные нечетные числа между двумя заданными числами.

Например, чтобы сгенерировать случайные четные или нечетные числа от10 до100, используйте следующие формулы:

=EVEN(RANDBETWEEN(10,100))(Генерирует случайные четные числа)
=ODD(RANDBETWEEN(10,100))
(Генерирует случайные нечетные числа)

Затем скопируйте формулу в другие нужные ячейки, перетянув маркер заполнения — результат будет, как показано на скриншотах ниже:

A screenshot showing random even numbers generated between 10 and 100 in Excel A screenshot showing random odd numbers generated between 10 and 100 in Excel

1.4 Генерация случайных чисел, сумма которых равна заданному значению

Иногда требуется создать набор случайных чисел, сумма которых равна заранее определенному значению. Например, я хочу сгенерировать5 или n случайных чисел от10 до50, чтобы их сумма была100, как показано на скриншоте ниже. Для решения этой задачи в Excel я расскажу о двух способах.

A screenshot showing the random numbers generated between 10 and 50 totaling 100 in Excel

Генерация случайных чисел, сумма которых равна определенному значению, с помощью формул

В этом случае помогут следующие формулы. Следуйте инструкции шаг за шагом, так как они немного сложные:

1. Сначала создайте необходимые данные: заданное итоговое значение, начальное и конечное число, а также количество случайных чисел, которые нужно сгенерировать, как показано на скриншоте ниже:

A screenshot showing the setup for generating random numbers that add up to a specific value in Excel, including bottom and top values and total

2. Затем скопируйте формулу ниже в пустую ячейку, где хотите сгенерировать числа. В этом примере формула будет в ячейке A4, нажмите Enter для получения первого случайного числа, см. скриншот:

=RANDBETWEEN(MAX($B$2,$A$2-(($D$2-ROWS($A$4:$A4))*$C$2)),MIN($C$2,$A$2-(($D$2-ROWS($A$4:$A4))*$B$2)))

Примечание: В формуле выше A2 — итоговое значение, B2 и C2 — нижнее и верхнее значения для генерации случайных чисел, D2 — количество случайных чисел, которые нужно сгенерировать, A4 — ячейка для ввода формулы.

A screenshot showing the result of the first random number generated using a formula in Excel

3. Далее скопируйте следующую формулу в ячейку A5 и нажмите Enter, чтобы получить второе случайное число, см. скриншот:

=IF(ROW()=$D$2+3,$A$2-SUM($A$4:$A4),IF(ROW()>$D$2+3,"",RANDBETWEEN(MAX($B$2,$A$2-(SUM($A$4:$A4)+($D$2-ROWS($A$4:$A5))*$C$2)),MIN($C$2,$A$2-(SUM($A$4:$A4)+($D$2-ROWS($A$4:$A5))*$B$2)))))

Примечание: В формуле выше A2 — итоговое значение, B2 и C2 — нижнее и верхнее значения для генерации случайных чисел, D2 — количество случайных чисел, которые нужно сгенерировать, A4 — ячейка для первой формулы, A5 — ячейка для второй формулы.

A screenshot showing the second random number generated using a formula and the updated result in Excel

4. Затем выделите второе сгенерированное число, перетащите вниз, чтобы скопировать формулу еще в три ячейки. Теперь вы получите5 случайных чисел, как показано на скриншоте ниже:

A screenshot showing the final set of random numbers generated that add up to a specific total in Excel

5. Чтобы проверить результат, сложите эти числа — сумма должна быть100. Нажмите F9 для обновления случайных чисел, их сумма всегда будет равна100.

A screenshot showing the sum of randomly generated numbers in Excel to verify their total


Генерация комбинаций случайных чисел, сумма которых равна определенному значению, с помощью удобной функции

С помощью приведенных выше формул можно сгенерировать случайные числа, соответствующие вашим требованиям. Если же вы хотите получить все возможные комбинации чисел из заданного набора с определенной суммой, рекомендую воспользоваться инструментом Kutools для Excel. С помощью функции Создать числа вы получите все наборы комбинаций случайных чисел с одинаковой суммой.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Сначала перечислите нужные числа. Здесь мы указали все числа от10 до50, как показано на скриншоте ниже:

A screenshot showing a list of numbers between 10 and 50 to find combinations that add up to a specific value in Excel

2. Затем нажмите Kutools > Текст > Создать числа, см. скриншот:

A screenshot of the Make Up A Number option under the Content group in Kutools tab in Excel

3. В появившемся диалоговом окне Создать числа выполните следующие действия:

  • В поле Исходный диапазон выберите список чисел, среди которых нужно найти те, сумма которых равна100;
  • В разделе Опции введите итоговое значение в поле Сумма. Здесь мы ввели100;
  • Установите флажок Сохранить в новом листе, если хотите вывести результат на новый лист;
  • Нажмите кнопку OK. См. скриншот:

A screenshot of the Make Up A Number dialog box with settings to generate number combinations summing to 100

4. После обработки вы увидите все наборы случайных чисел с общей суммой100, состоящие из чисел от10 до50, как показано ниже.

A screenshot showing the results of all random number combinations summing to 100 generated using Kutools

Совет: Вы можете дополнительно указать количество комбинаций и количество случайных чисел в каждой комбинации. Например, чтобы сгенерировать10 комбинаций по5 случайных чисел, настройте параметры в диалоговом окне в разделе Расширенные настройки следующим образом:

A screenshot of the Make Up A Number dialog box with advanced settings to specify the number of combinations and numbers per combination in Excel

В результате вы получите следующий результат:

A screenshot showing results of random number combinations generated based on advanced settings


1.5 Генерация случайных букв и текстовых строк с помощью формул

В этом разделе показано, как сгенерировать случайные буквы в Excel, например, прописные буквы от A до Z, строчные буквы от a до z или некоторые специальные символы (! " # $ % & ' ( ) * + , - . /).

Генерация случайных букв и текстовых строк с помощью формул

В Excel можно объединить функции CHAR и RANDBETWEEN с некоторыми ANSI-кодами символов для создания формул, как показано ниже:

Формула Описание
=CHAR(RANDBETWEEN(65,90)) Генерирует случайные прописные буквы от A до Z.
=CHAR(RANDBETWEEN(97,122)) Генерирует случайные строчные буквы от a до z.
=CHAR(RANDBETWEEN(33,47)) Генерирует случайные специальные символы, такие как: ! " # $ % & ' ( ) * + , - . /

Примените любую из приведенных выше формул по необходимости и скопируйте ее в нужное количество ячеек — результат будет, как показано на скриншотах ниже:

=CHAR(RANDBETWEEN(65,90)) =CHAR(RANDBETWEEN(97,122)) =CHAR(RANDBETWEEN(33,47))
A screenshot showing random uppercase letters generated using the formula =CHAR(RANDBETWEEN(65,90)) in Excel A screenshot showing random lowercase letters generated using the formula =CHAR(RANDBETWEEN(97,122)) in Excel A screenshot showing random special characters generated using the formula =CHAR(RANDBETWEEN(33,47)) in Excel

Совет: Если вы хотите сгенерировать случайные текстовые строки из нескольких букв, просто используйте символ & для объединения букв в нужном количестве.

1.) Чтобы сгенерировать случайную строку из четырех прописных букв, используйте формулу ниже:

=CHAR(RANDBETWEEN(65,90))& CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(65,90))

A screenshot showing random strings with four uppercase letters generated using a combined formula in Excel

2.) Чтобы сгенерировать случайную строку из четырех строчных букв, используйте формулу ниже:

=CHAR(RANDBETWEEN(97,122))& CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122))

3.) Чтобы сгенерировать строку, где первые две буквы прописные, а последние две — строчные, используйте формулу ниже:

=CHAR(RANDBETWEEN(65,90))& CHAR(RANDBETWEEN(65,90)) & CHAR(RANDBETWEEN(97,122)) & CHAR(RANDBETWEEN(97,122))

Вы можете использовать простые формулы и символ & для создания различных комбинаций по вашему желанию.


Генерация случайных букв и текстовых строк с помощью удобной функции

Если у вас установлен Kutools для Excel, вы сможете быстро и легко сгенерировать случайные буквы и строки без необходимости запоминать формулы.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек для вставки букв или строк.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные, в появившемся диалоговом окне выполните следующие действия:

  • Перейдите на вкладку Строка;
  • Отметьте a-z или A-Z, или оба варианта, которые вы хотите вставить;
  • Затем укажите длину строки в поле Длина;
  • В конце нажмите ОК или Применить, чтобы вставить строки, как показано на скриншоте ниже.

A screenshot showing the Insert Random Data dialog box for generating random letters and strings in Excel


1.6 Генерация случайных паролей с буквенно-цифровыми символами в Excel

При создании пароля он должен содержать не менее8 символов и включать прописные и строчные буквы, цифры и специальные символы. В этом разделе я расскажу о некоторых приемах генерации случайных паролей в Excel.

Генерация случайных паролей с буквенно-цифровыми символами с помощью формул

Например, здесь я создам случайные пароли длиной8 символов. Просто объедините три формулы, приведенные в разделе Генерация случайных букв и текстовых строк с помощью формул.

Скопируйте формулу ниже в пустую ячейку:

=CHAR(RANDBETWEEN(65,90))&CHAR(RANDBETWEEN(97,122))&CHAR(RANDBETWEEN(97,122))&CHAR(RANDBETWEEN(65,90))&RANDBETWEEN(100,999)&CHAR(RANDBETWEEN(33,47))

Примечание: В формуле выше первая пара функций CHAR и RANDBETWEEN генерирует случайную прописную букву, вторая и третья — две строчные буквы, четвертая — еще одну прописную букву, пятая — трехзначное число от100 до999, последняя — специальный символ. Вы можете изменить порядок или состав по своему усмотрению.

A screenshot showing random passwords generated using the formula combining CHAR and RANDBETWEEN functions in Excel


Генерация случайных паролей с буквенно-цифровыми символами с помощью пользовательской функции

Чтобы вставить случайные пароли в Excel, используйте следующую пользовательскую функцию — выполните следующие действия:

1. Удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставка > Модуль и вставьте следующий макрос в окно модуля.

VBA-код: Генерация случайных паролей в Excel

Function RandomizeF(Num1 As Integer, Num2 As Integer)
'Updateby Extendoffice
Dim Rand As String
Application.Volatile
getLen = Int((Num2 + 1 - Num1) * Rnd + Num1)
Do
    i = i + 1
    Randomize
    Rand = Rand & Chr(Int((85) * Rnd + 38))
Loop Until i = getLen
RandomizeF = Rand
End Function

3. Затем закройте код и вернитесь на лист. В ячейке введите формулу =RandomizeF(8,10), чтобы сгенерировать случайную строку длиной от8 до10 символов.

4. Затем перетащите и скопируйте формулу в другие ячейки по необходимости. Будут созданы случайные строки с буквенно-цифровыми и специальными символами длиной от8 до10 символов. См. скриншот:

A screenshot showing random passwords generated using the VBA function RandomizeF


Генерация случайных паролей с буквенно-цифровыми символами с помощью простой функции

Есть ли быстрый и простой способ сгенерировать несколько случайных паролей в Excel? Kutools для Excel предлагает отличную функцию — Вставить случайные данные. С ее помощью вы сможете вставить случайные пароли всего за несколько кликов.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек для вставки паролей.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные. В появившемся диалоговом окне выполните следующие действия:

  • Перейдите на вкладку Строка;
  • Отметьте нужные типы символов;
  • Затем укажите длину пароля в поле Длина;
  • В конце нажмите ОК или Применить, чтобы сгенерировать пароли, как показано на скриншоте ниже.

A screenshot showing random passwords generated using the Insert Random Data feature of Kutools


1.7 Генерация случайных заданных текстов в Excel

Пробовали ли вы когда-нибудь случайным образом отображать или перечислять определенные текстовые значения в Excel? Например, чтобы случайно распределить заданные тексты (item1, item2, item3, item4, item5) по списку ячеек, воспользуйтесь одним из двух способов ниже.

Генерация случайных заданных текстов с помощью формулы

В Excel можно создать формулу на основе функций CHOOSE и RANDBETWEEN для случайного распределения заданных текстов. Общий синтаксис:

=CHOOSE(RANDBETWEEN(1,n),"Value_1","Value_2","Value_3",…"Value_n")
  • Value_1, Value_2, Value_3, Value_n : представляют текстовые значения, которые вы хотите случайно распределить;
  • n : количество текстовых значений, которые вы хотите использовать.

Примените формулу ниже в пустую ячейку, затем перетащите маркер заполнения вниз, чтобы заполнить ячейки случайными значениями, см. скриншот:

=CHOOSE(RANDBETWEEN(1,5),"Chemistry","Physics","Geography","Biology","Economics")

A screenshot showing random specific texts generated using the CHOOSE and RANDBETWEEN functions in Excel


Генерация случайных заданных текстов с помощью быстрого метода

Если у вас есть Kutools для Excel, функция Вставить случайные данные также поможет случайным образом вставить пользовательские текстовые значения в диапазон ячеек.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек для вставки заданных текстов.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные, в появившемся диалоговом окне выполните следующие действия:

  • Перейдите на вкладку Пользовательский список;
  • Затем нажмите Add button кнопку, чтобы открыть другое Kutools for Excel диалоговое окно, введите или выберите свои пользовательские текстовые значения, которые вы хотите случайно распределить. (При ручном вводе значения должны быть разделены запятыми.)

A screenshot of the Kutools for Excel prompt box for entering custom text values in the Insert Random Data dialog

3. Затем нажмите ОК для возврата в диалог Вставить случайные данные, ваш пользовательский список текстов появится в списке. Теперь выберите новые элементы списка, нажмите ОК или Применить, чтобы случайно вставить значения в выделенные ячейки.

A screenshot showing custom random texts inserted into a range using the Kutools Insert Random Data feature in Excel

Совет: Чтобы случайно распределить заданные тексты без повторов, установите флажок Сгенерировать уникальные значения.


1.8 Генерация или выбор случайных значений из списка в Excel

Предположим, у вас есть длинный список имен, и вы хотите выбрать из него несколько случайных имен для розыгрыша или исследования, как показано на скриншоте ниже. Как это сделать в Excel?

A screenshot showing a long list of names to be randomly selected in Excel

Генерация случайных значений из списка с помощью функций INDEX, RANDBETWEEN и ROWS

В Excel нет прямого способа выбрать случайные значения из списка, но можно создать формулу на основе функций INDEX, RANDBETWEEN и ROWS для извлечения случайных значений.

1. Скопируйте формулу ниже в пустую ячейку, где хотите получить извлеченное значение:

=INDEX($A$2:$A$12,RANDBETWEEN(1,ROWS($A$2:$A$12)),1)

Примечание: В формуле выше A2:A12 — список значений, из которого вы хотите выбрать случайные значения.

2. Затем перетащите маркер заполнения вниз на нужное количество ячеек, чтобы отобразить случайные значения — результат будет, как показано на скриншоте:

A screenshot showing random names extracted from a list using the INDEX, RANDBETWEEN, and ROWS functions in Excel


Генерация случайных значений из списка без повторов с помощью функций INDEX, RANK.EQ

При использовании формулы выше могут появляться дубликаты. Чтобы избежать повторов, сначала создайте вспомогательный столбец, затем примените формулу на основе функций INDEX и RANK.EQ. Выполните следующие действия:

1. Введите формулу ниже в пустую ячейку для получения списка случайных чисел, см. скриншот:

=RAND()

A screenshot showing a list of random numbers generated as a helper column for unique selection in Excel

2. Затем скопируйте формулу ниже в ячейку другого столбца, где хотите извлечь случайные значения, и перетащите ее вниз, чтобы отобразить несколько уникальных случайных значений, см. скриншот:

=INDEX($A$2:$A$12,RANK.EQ($B2,$B$2:$B$12))

Примечание: В формуле выше A2:A12 — список значений, из которого вы хотите получить случайные значения, B2 — первая ячейка вспомогательного столбца, B2:B12 — ячейки с формулой из шага1.

A screenshot showing random unique names selected using the INDEX and RANK.EQ functions in Excel


Выбор случайных ячеек, строк, столбцов из диапазона с помощью отличной функции

Здесь я рекомендую удобную функцию — Сортировать, выбирать или случайно перемешивать Kutools для Excel. С ее помощью вы сможете выбрать случайные ячейки, строки или столбцы по необходимости.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите список ячеек, из которых хотите выбрать случайные значения.

2. Затем нажмите Kutools > Диапазон > Сортировать, выбирать или случайно перемешивать, см. скриншот:

A screenshot showing the Sort/Select Range Randomly feature in Kutools tab in Excel

3. В диалоговом окне Сортировать, выбирать или случайно перемешивать выполните следующие действия:

  • Перейдите на вкладку Выбрать;
  • Затем в поле Количество выбираемых ячеек для выбора укажите, сколько ячеек нужно выбрать случайным образом;
  • В разделе Тип выбора выберите нужную операцию. В данном случае выберите опцию Ячейка.
  • Затем нажмите ОК или Применить — пять ячеек будут выбраны случайным образом, см. скриншоты:

A screenshot showing the result of randomly selected cells using the Kutools Sort/Select Range Randomly feature

4. После выбора ячеек вы можете скопировать и вставить их в другие ячейки по необходимости.


1.9 Случайное распределение данных по группам в Excel

Допустим, у вас есть список имен, и вы хотите случайным образом разделить их на три группы (Группа A, Группа B, Группа C), как показано на скриншоте ниже. В этом разделе рассмотрим формулы для решения этой задачи в Excel.

A screenshot showing names divided into three groups randomly in Excel

Случайное распределение данных по группам с помощью формулы

Чтобы случайным образом распределить людей по заданным группам, используйте функцию CHOOSE в сочетании с функцией RANDBETWEEN.

1. Скопируйте или введите формулу ниже в ячейку, где хотите получить группу:

=CHOOSE(RANDBETWEEN(1,3),"Group A","Group B","Group C")

Примечание: В формуле выше Group A, Group B и Group C — это имена групп, которые вы хотите назначить, а число3 — количество групп для распределения.

2. Затем перетащите маркер заполнения, чтобы скопировать формулу в другие ячейки — имена будут разделены на три группы, как показано на скриншоте ниже:

A screenshot showing random group assignments using CHOOSE and RANDBETWEEN functions in Excel


Случайное распределение данных по группам с равным количеством с помощью формулы

Если вы хотите, чтобы во всех группах было одинаковое количество имен, формула выше не подойдет. В этом случае создайте вспомогательный столбец со случайными значениями с помощью функции RAND, затем примените формулу на основе функций INDEX, RANK и ROUNDUP.

Например, я перечислил имена групп в ячейках F2:F4. Чтобы распределить людей по группам (Группа A, Группа B, Группа C), и в каждой группе было по4 участника, выполните следующие действия:

1. Введите формулу: =RAND() в пустую ячейку для получения списка случайных чисел, см. скриншот:

A screenshot showing random numbers generated as a helper column for dividing data into equal groups in Excel

2. Затем в следующем столбце, например, в ячейке D2, скопируйте или введите формулу ниже:

=INDEX($F$2:$F$4, ROUNDUP(RANK(C2,$C$2:$C$13)/4,0))

Примечание: В формуле выше C2 — первая ячейка вспомогательного столбца, C2:C13 — ячейки с формулой из шага1, число4 — сколько имен должно быть в каждой группе, F2:F4 — диапазон ячеек с именами групп.

3. Перетащите маркер заполнения вниз, чтобы сгенерировать случайные группы для списка данных — имена будут равномерно распределены по группам, см. скриншот:

A screenshot showing names evenly divided into three groups using formulas in Excel


1.10 Генерация случайных дат в Excel

Чтобы сгенерировать произвольные даты между двумя заданными датами, я расскажу о нескольких способах.

Генерация случайных дат между двумя заданными датами с помощью формул

Например, я хочу случайным образом сгенерировать даты между2021-05-01 и2021-10-15. Обычно в Excel это можно сделать с помощью комбинации функций RANDBETWEEN и DATE — выполните следующие действия:

1. Выделите ячейку, куда хотите вставить случайную дату, и введите формулу:

=RANDBETWEEN(DATE(2021,5,1),DATE(2021,10,15))

Примечание: В этой формуле2021,5,1 — начальная дата, а2021,10,15 — конечная дата. Вы можете заменить их по необходимости.

2. Затем перетащите и скопируйте формулу в другие ячейки, которые хотите заполнить — в ячейках появятся пятизначные числа, как показано на скриншоте ниже:

A screenshot showing five-digit numbers generated by the RANDBETWEEN function for random dates

3. Затем отформатируйте числа как даты. Выделите ячейки с формулой, щелкните правой кнопкой мыши и выберите Формат ячеек в контекстном меню.

4. В диалоговом окне Формат ячеек перейдите на вкладку Число, выберите Дата в списке Категория и выберите нужный формат даты в списке Тип. См. скриншот:

A screenshot of the Format Cells dialog box used to format numbers as dates in Excel

5. Нажмите OK для закрытия диалога. Теперь числа преобразованы в обычные даты. См. скриншот:

A screenshot showing random dates generated between 2021-5-1 and 2021-10-15 in Excel after formatting

Совет: Чтобы сгенерировать случайные рабочие дни, исключая выходные, используйте формулу ниже:

=WORKDAY(RANDBETWEEN(DATE(2021,5,1),DATE(2021,10,15))-1,1)

Генерация случайных дат между двумя заданными датами с помощью удобной функции

Функция Вставить случайные данные Kutools для Excel также позволяет сгенерировать случайные даты, рабочие дни и выходные между двумя заданными датами.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек для вставки случайных дат.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные, в появившемся диалоговом окне выполните следующие действия:

  • Перейдите на вкладку Дата;
  • Затем укажите область дат. В этом примере я выберу с5/1/2021 по10/15/2021.
  • Затем выберите тип даты — рабочий день, выходной или оба варианта по необходимости.
  • В конце нажмите ОК или Применить, чтобы случайным образом сгенерировать даты, как показано на скриншоте ниже.

A screenshot showing random workdays generated between two dates using Kutools

Совет: Чтобы сгенерировать уникальные случайные даты, установите флажок Сгенерировать уникальные значения.


1.11 Генерация случайного времени в Excel

После вставки случайных чисел, текстовых строк и дат в этом разделе я расскажу о приемах генерации случайного времени в Excel.

Генерация случайного времени с помощью формул

Генерация случайного времени с помощью формулы

Чтобы сгенерировать случайное время в диапазоне ячеек, используйте формулу на основе функций TEXT и RAND.

Введите формулу ниже в пустую ячейку, затем перетащите и скопируйте ее в другие ячейки, где хотите получить время, см. скриншот:

=TEXT(RAND(),"HH:MM:SS")

A screenshot showing the result of using the TEXT and RAND functions to generate random times in Excel


Генерация случайного времени между двумя заданными моментами с помощью формулы

Если нужно случайно вставить время между двумя определенными моментами, например, от10 до18 часов, используйте формулу ниже:

=TEXT(RAND()*(18-10)/24+10/24,”HH:MM:SS”)

Примечание: В формуле выше число18 — это конечное время, а10 — начальное время. Вы можете изменить их по своему усмотрению.

Затем перетащите и скопируйте формулу в другие ячейки, чтобы сгенерировать случайное время между двумя диапазонами времени, см. скриншот:

A screenshot showing random times generated between 10 AM and 6 PM using a formula


Генерация случайного времени с определенным интервалом с помощью формулы

Например, если вы хотите сгенерировать случайное время с определенным интервалом, например, с шагом15 минут, используйте функции RAND и FLOOR внутри функции TEXT.

Скопируйте или введите формулу ниже в пустую ячейку, затем перетащите и скопируйте ее в нужные ячейки, см. скриншот:

=TEXT(FLOOR(RAND(),"0:15"),"HH:MM:SS")

Примечание: В формуле число15 — это интервал времени. Если нужно случайное время с интервалом30 минут, просто замените15 на30.

A screenshot showing random times generated at 15-minute intervals using a formula in Excel


Генерация случайного времени между двумя заданными моментами с помощью удобной функции

Если у вас есть Kutools для Excel, функция Вставить случайные данные также поможет сгенерировать случайное время между заданными моментами на листе.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите диапазон ячеек для генерации времени.

2. Затем нажмите Kutools > Вставка > Вставить случайные данные, в появившемся диалоговом окне выполните следующие действия:

  • Перейдите на вкладку Время;
  • Затем укажите диапазон времени. В этом примере я выберу с9:00 до16:30.
  • В конце нажмите ОК или Применить, чтобы сгенерировать случайное время, как показано на скриншоте ниже.

A screenshot of Kutools for Excel generating random times between 9:00 AM and 4:30 PM using the Insert Random Data tool


Генерация случайных дат и времени между двумя датами с помощью формулы

Если вы хотите сгенерировать случайные даты и время одновременно, используйте формулу ниже.

1. Введите или скопируйте формулу ниже в ячейку, где хотите получить случайные дату и время:

=TEXT(RAND()*("2021-10-1512:00:00"-"2021-1-19:00")+"2021-1-19:00:00","YYYY-MM-DD HH:MM:SS")

Примечание: В формуле2021-10-1512:00:00 — конечная дата и время, а2021-1-19:00:00 — начальная дата и время. Вы можете изменить их по своему усмотрению.

2. Затем перетащите и скопируйте формулу в другие ячейки, где хотите отобразить случайные дату и время, см. скриншот:

A screenshot showing random date-time values generated using a formula in Excel between 2021-01-01 9:00:00 and 2021-10-15 12:00:00


Генерация случайных чисел, текстов, дат в Excel365 /2021 и более новых версиях

В этом разделе показано, как с помощью новой динамической функции массива RANDARRAY генерировать случайные числа, даты, выбирать случайные значения и случайно распределять данные по группам в Excel365, Excel2021 и будущих версиях.

Функция RANDARRAY возвращает массив случайных чисел между любыми двумя указанными вами числами.

Синтаксис функции RANDARRAY:

=RANDARRAY([rows],[columns],[min],[max],[integer])
  • rows (необязательно): количество строк случайных чисел для возврата; (если не указано, по умолчанию =1)
  • columns (необязательно): количество столбцов случайных чисел для возврата; (если не указано, по умолчанию =1)
  • min (необязательно): минимальное возвращаемое число; (если не указано, по умолчанию =0)
  • max (необязательно): максимальное возвращаемое число; (если не указано, по умолчанию =1)
  • integer (необязательно): возвращать целое или десятичное число. TRUE — целое число, FALSE — десятичное. (если не указано, по умолчанию =FALSE)
Примечания:
  • 1. В функции RANDARRAY пять аргументов, все они необязательные. Если ни один не указан, функция вернет десятичное число от0 до1.
  • 2. Если аргументы rows или columns — десятичные числа, они будут округлены до целого числа вниз (например,3.9 будет считаться как3).
  • 3. Минимальное число должно быть меньше максимального, иначе будет возвращена ошибка #VALUE!.
  • 4. Функция RANDARRAY возвращает массив, и если она возвращает несколько результатов на листе, они будут заполнять соседние ячейки.

2.1 Генерация случайных чисел в Excel365 /2021 и более новых версиях

Чтобы сгенерировать случайные целые или десятичные числа в Excel365, Excel2021 и будущих версиях, используйте новую функцию RANDARRAY.

Генерация случайных чисел между двумя числами с помощью формулы

Чтобы создать список случайных чисел в определенном диапазоне, примените одну из формул ниже:

Введите любую из формул ниже по необходимости и нажмите Enter для получения результата, см. скриншоты:

=RANDARRAY(6,4,50,200, TRUE) (Генерирует случайные целые числа от50 до200)
=RANDARRAY(6,4,50,200, FALSE)
(Генерирует случайные десятичные числа от50 до200)
Примечание: В формулах выше:
  • 6: возвращает6 строк случайных чисел;
  • 4: возвращает4 столбца случайных чисел;
  • 50,200: минимальное и максимальное значения, между которыми нужно сгенерировать числа;
  • TRUE: возвращает целые числа;
  • FALSE: возвращает десятичные числа.
A screenshot showing random integers generated between 50 and 200 using the RANDARRAY function A screenshot showing random decimals generated between 50 and 200 using the RANDARRAY function in Excel

Генерация случайных чисел без повторов с помощью формул

При использовании обычной функции RANDARRAY для генерации случайных чисел могут появляться дубликаты. Чтобы избежать повторов, ниже приведены формулы для решения задачи.

Генерация списка уникальных случайных чисел

Чтобы случайным образом сгенерировать столбец или список уникальных чисел, используйте следующий общий синтаксис:

Случайные целые числа без повторов:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, TRUE)), SEQUENCE(n))

Случайные десятичные числа без повторов:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, FALSE)), SEQUENCE(n))
  • n: количество значений, которые вы хотите сгенерировать;
  • min: минимальное значение;
  • max: максимальное значение.

Например, чтобы вставить список из8 случайных чисел от50 до100 без повторов, примените любую из формул ниже и нажмите Enter для получения результата:

=INDEX(UNIQUE(RANDARRAY(8^2,1,50,100, TRUE)), SEQUENCE(8)) (Уникальные случайные целые числа)
=INDEX(UNIQUE(RANDARRAY(8^2,1,50,100, FALSE)), SEQUENCE(8))
(Уникальные случайные десятичные числа)
Примечание: В формулах выше:
  • 8: возвращает8 случайных чисел;
  • 50,100: минимальное и максимальное значения, между которыми нужно сгенерировать числа.
  • TRUE: возвращает целые числа;
  • FALSE: возвращает десятичные числа.
A screenshot showing a list of unique random integers generated using the UNIQUE and RANDARRAY functions in Excel A screenshot showing a list of unique random decimals generated using the UNIQUE and RANDARRAY functions in Excel

Генерация диапазона уникальных случайных чисел

Если нужно сгенерировать уникальные случайные числа в диапазоне ячеек, просто укажите количество строк и столбцов в функции SEQUENCE. Общий синтаксис:

Чтобы случайным образом сгенерировать столбец или список уникальных чисел, используйте следующий общий синтаксис:

Случайные целые числа без повторов:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, TRUE)), SEQUENCE(rows, columns))

Случайные десятичные числа без повторов:

=INDEX(UNIQUE(RANDARRAY(n^2,1, min, max, FALSE)), SEQUENCE(rows, columns))
  • n: количество ячеек для вставки чисел, можно указать как количество строк * количество столбцов; например, для заполнения8 строк и3 столбцов используйте24^2.
  • rows: количество строк для заполнения;
  • columns: количество столбцов для заполнения;
  • min: минимальное значение;
  • max: максимальное значение.

Здесь я заполню диапазон из8 строк и3 столбцов уникальными случайными числами от50 до100 — используйте любую из формул ниже:

=INDEX(UNIQUE(RANDARRAY(24^2,1,50,100, TRUE)), SEQUENCE(8,3)) (Уникальные случайные целые числа)
=INDEX(UNIQUE(RANDARRAY(24^2,1,50,100, FALSE)), SEQUENCE(8,3))
(Уникальные случайные десятичные числа)
Примечание: В формулах выше:
  • 24: возвращает24 случайных числа, произведение8 и3 (строк*столбцов);
  • 50,100: минимальные и максимальные значения, между которыми нужно сгенерировать числа;
  • TRUE: возвращает целые числа;
  • FALSE: возвращает десятичные числа.
A screenshot showing a grid of unique random integers generated in 8 rows and 3 columns using Excel's RANDARRAY function A screenshot showing a grid of unique random decimals generated in 8 rows and 3 columns using Excel's RANDARRAY function

2.2 Генерация случайных дат в Excel365 /2021 и более новых версиях

С помощью новой функции RANDARRAY вы также сможете быстро и легко сгенерировать несколько случайных дат или рабочих дней в Excel.

Генерация случайных дат между двумя датами с помощью формулы

Чтобы создать список случайных дат между двумя конкретными датами, используйте формулу ниже:

1. Введите формулу ниже в пустую ячейку для генерации случайных дат и нажмите Enter, чтобы получить список пятизначных чисел, см. скриншот:

=RANDARRAY(10,1, B1, B2, TRUE)
Примечание: В формулах выше:
  • 10: возвращает10 строк случайных дат;
  • 1: возвращает1 столбец случайных дат;
  • B1, B2: ячейки с начальной и конечной датой, между которыми нужно сгенерировать даты.

A screenshot showing five-digit random dates generated using RANDARRAY between two dates in Excel

2. Затем отформатируйте числа в обычный формат даты: выделите числа, щелкните правой кнопкой мыши и выберите Формат ячеек в контекстном меню. В появившемся диалоговом окне Формат ячеек выполните следующие действия:

  • Перейдите на вкладку Число;
  • Затем выберите Дата в списке Категория;
  • Затем выберите нужный формат даты в списке Тип.

A screenshot of the Format Cells dialog box used to format random numbers as dates in Excel

3. Затем нажмите кнопку OK — числа будут отформатированы как даты, см. скриншот:

A screenshot showing formatted random dates between May 1, 2021, and December 31, 2021, using Excel

Совет: Конечно, вы можете ввести начальную и конечную дату прямо в формулу, как показано ниже:

=RANDARRAY(10,1, "5/1/2021", "12/31/2021", TRUE)

Генерация случайных рабочих дней между двумя датами с помощью формулы

Чтобы получить случайные рабочие дни в диапазоне ячеек, вложите функцию RANDARRAY в функцию WORKDAY.

1. Введите или скопируйте формулу ниже в пустую ячейку, затем нажмите Enter, чтобы получить список чисел, как показано на скриншоте ниже:

=WORKDAY(RANDARRAY(10,1, B1, B2, TRUE),1)

A screenshot showing random workday numbers generated using RANDARRAY and WORKDAY functions in Excel

2. Затем отформатируйте числа в нужный формат даты в диалоговом окне Формат ячеек — вы получите формат даты, как показано на скриншоте ниже:

A screenshot showing random workdays formatted as dates in Excel

Совет: Вы также можете ввести начальную и конечную дату прямо в формулу, как показано ниже:

=WORKDAY(RANDARRAY(10,1, "5/1/2021", "12/31/2021", TRUE),1)

2.3 Генерация или получение случайных значений из списка в Excel365 /2021 и более новых версиях

В Excel365, Excel2021 и будущих версиях (например, Excel2024), если вы хотите сгенерировать или вернуть случайные значения из списка ячеек, в этом разделе приведены формулы для решения задачи.

Генерация или получение случайных значений из списка с помощью формулы

Для извлечения случайных значений из списка ячеек используйте функцию RANDARRAY вместе с функцией INDEX. Общий синтаксис:

=INDEX(data, RANDARRAY(n,1,1, ROWS(data), TRUE))
  • data: список значений, из которого вы хотите извлечь случайные элементы;
  • n: количество случайных элементов, которые вы хотите извлечь.

Например, чтобы извлечь3 имени из списка имен A2:A12, используйте формулы ниже:

=INDEX(A2:A12, RANDARRAY(C2,1,1, ROWS(A2:A12), TRUE))(Использовать ссылку на ячейку)
=INDEX(A2:A12, RANDARRAY(3,1,1, ROWS(A2:A12), TRUE))
(Ввести число напрямую)

Затем нажмите Enter, чтобы сразу получить3 случайных имени, см. скриншот:

A screenshot of random names extracted from a list in Excel


Генерация или получение случайных значений из списка без повторов с помощью формулы

В формуле выше могут появляться дубликаты. Чтобы случайно выбрать значения из списка без повторов, используйте следующий общий синтаксис:

=INDEX(SORTBY(data, RANDARRAY(ROWS(data))), SEQUENCE(n))
  • data: список значений, из которого вы хотите извлечь случайные элементы;
  • n: количество случайных элементов, которые вы хотите извлечь.

Если нужно вернуть5 случайных имен из списка A2:A12, введите или скопируйте одну из формул ниже:

=INDEX(SORTBY(A2:A12, RANDARRAY(ROWS(A2:A12))), SEQUENCE(C2))(Использовать ссылку на ячейку)
=INDEX(SORTBY(A2:A12, RANDARRAY(ROWS(A2:A12))), SEQUENCE(5))             
(Ввести число напрямую)

Затем нажмите Enter, чтобы получить5 случайных имен из списка A2:A12 без повторов, см. скриншот:

A screenshot of random names extracted from a list in Excel without duplicates


2.4 Генерация или выбор случайных строк из диапазона в Excel365 /2021 и более новых версиях

Иногда может понадобиться выбрать случайные строки из диапазона ячеек в Excel. Для этого ниже приведены формулы.

Генерация или выбор случайных строк из диапазона с помощью формулы

Общий синтаксис для генерации случайных строк из диапазона ячеек:

=INDEX(data, RANDARRAY(n,1,1, ROWS(data), TRUE), {1,2,3…})
  • data: диапазон ячеек, из которого вы хотите извлечь случайные строки;
  • n: количество случайных строк, которые вы хотите извлечь;
  • {1,2,3…}: номера столбцов для извлечения.

Чтобы извлечь3 строки данных из диапазона A2:C12, используйте любую из формул ниже:

=INDEX(A2:C12, RANDARRAY(E2,1,1, ROWS(A2:C12), TRUE), {1,2,3})(Использовать ссылку на ячейку)
=INDEX(A2:C12, RANDARRAY(3,1,1, ROWS(A2:C12), TRUE), {1,2,3})
(Ввести число напрямую)

Затем нажмите Enter, чтобы получить3 случайные строки данных из диапазона A2:C12, см. скриншот:

A screenshot of 3 random rows extracted from a range in Excel


Генерация или выбор случайных строк из диапазона без повторов с помощью формулы

Аналогично, формула выше может возвращать дублирующиеся данные. Чтобы избежать повторов строк, используйте следующий общий синтаксис:

=INDEX(SORTBY(data, RANDARRAY(ROWS(data))), SEQUENCE(n), {1,2,3…})
  • data: диапазон ячеек, из которого вы хотите извлечь случайные строки;
  • n: количество случайных строк, которые вы хотите извлечь;
  • {1,2,3…}: номера столбцов для извлечения.

Например, чтобы выбрать5 строк данных из диапазона A2:C12, используйте любую из формул ниже:

=INDEX(SORTBY(A2:C12, RANDARRAY(ROWS(A2:C12))), SEQUENCE(E2), {1,2,3})(Использовать ссылку на ячейку)
=INDEX(SORTBY(A2:C12, RANDARRAY(ROWS(A2:C12))), SEQUENCE(5), {1,2,3})             
(Ввести число напрямую)

Затем нажмите Enter —5 случайных строк без повторов будут извлечены из диапазона A2:C12, как показано на скриншоте ниже:

A screenshot of 5 random rows extracted from a range in Excel without duplicates


Как зафиксировать случайные результаты, чтобы они не изменялись

Вы, вероятно, заметили, что все функции для генерации случайных данных, такие как RAND, RANDBETWEEN и RANDARRAY, являются изменяемыми. Результаты будут пересчитываться при каждом изменении листа, и появятся новые случайные значения. Чтобы остановить автоматическое изменение случайных значений, ниже приведены два быстрых способа.

Как зафиксировать случайные результаты с помощью копирования и вставки

Обычно можно воспользоваться функцией Копировать и Вставить, чтобы скопировать и вставить динамические формулы как значения — выполните следующие действия:

1. Выделите ячейки с вашей случайной формулой и нажмите Ctrl + C для копирования.

2. Затем щелкните правой кнопкой мыши выделенный диапазон и выберите Значения в разделе Параметры вставки, см. скриншот:

Совет: Можно также нажать Shift + F10, а затем V для активации этой опции.

A screenshot of the 'Values' option in Excel's Paste Options menu

3. Все ячейки с формулами будут преобразованы в значения, и случайные значения больше не будут изменяться.


Как зафиксировать случайные результаты с помощью удобной функции

Если у вас установлен Kutools для Excel, функция К фактическим поможет преобразовать все выбранные ячейки с формулами в значения одним кликом.

Kutools для Excel предлагает более 300 продвинутых функций для упрощения сложных задач, повышая креативность и эффективность. Интеграция с возможностями ИИ позволяет Kutools автоматизировать задачи с высокой точностью, делая управление данными без усилий. Подробная информация о Kutools для Excel...  Бесплатная пробная версия...

1. Выделите ячейки со случайной формулой и нажмите Kutools > К фактическим, см. скриншот:

A screenshot of the Kutools 'To Actual' feature in Excel

2. Теперь все выбранные формулы преобразованы в значения.

Лучшие инструменты для повышения продуктивности работы с Office

🤖 Kutools AI Aide: Совершенно новый подход к анализу данных на основе: Интеллектуальное выполнение |  Генерация кода  |  Создание пользовательских формул |  Анализ данных и построение диаграмм  |  Вызов Расширенных функций Kutools
Популярные функции: Найти, выделить или отметить дубликаты | Удалить пустые строки | Объединить столбцы или ячейки без потери данных |   Округлить без формулы ...
Супер ПОИСК: VLOOKUP по нескольким критериям | VLOOKUP с несколькими значениями | Многолистовой поиск | Распознавание нечетких соответствий ....
Расширенный раскрывающийся список: Быстро создать раскрывающийся список | Зависимый раскрывающийся список | Множественный выбор в раскрывающемся списке ....
Менеджер столбцов: Добавить определённое количество столбцов | Переместить столбцы | Переключить видимость скрытых столбцов | Сравнить диапазоны и столбцы ...
Избранные функции: Сетка фокусировки | Дизайн листа | Улучшенная строка формулы | Управление книгами и листами | Библиотека автотекста | Выбор даты | Объединить данные | Шифрование/расшифровка ячеек | Отправить письмо по списку | Супер фильтр | Специальный фильтр (фильтр ячеек с жирным/курсивом/зачёркнутым...) ...
Топ-15 наборов инструментов:12 текстовых инструментов (Добавить текст, Удалить определенные символы, ...) |50+ типов диаграмм (Диаграмма Ганта, ...) |40+ практических формул (Расчет возраста на основе даты рождения, ...) |19 инструментов вставки (Вставить QR-код, Вставить изображение по пути, ...) |12 инструментов преобразования (Преобразовать в слова, Конвертация валюты, ...) |7 инструментов для объединения и разделения (Расширенное объединение строк, Разделить ячейки, ...) | ... и многое другое

Ускорьте работу в Excel с Kutools для Excel и ощутите новую степень эффективности. Kutools для Excel предлагает более300 расширенных функций для повышения продуктивности и экономии времени. Нажмите здесь, чтобы выбрать нужную вам функцию...


Office Tab добавляет вкладки в Office и делает вашу работу намного проще

  • Включите редактирование и чтение с вкладками в Word, Excel, PowerPoint, Publisher, Access, Visio и Project.
  • Открывайте и создавайте несколько документов во вкладках одного окна, а не в отдельных окнах.
  • Увеличьте свою продуктивность на50% и сократите сотни лишних кликов мышью каждый день!