Как запустить несколько макросов из контекстного меню в Excel?

Если в вашей книге несколько макросов vba, вы должны открыть окно VBA, а затем выбрать макрос, когда вам нужно запустить код. В этой статье я хотел бы поговорить о том, как запускать макросы из контекстного меню, чтобы сделать вашу работу более эффективной, как показано на скриншоте слева.

Запускать несколько макросов из контекстного меню с кодами VBA

Запускать несколько макросов из контекстного меню с кодами VBA

Чтобы запустить коды макросов в книге из контекстного меню, вам могут помочь следующие шаги: сделайте следующее:

1. Дырка вниз Alt + F11 , чтобы открыть Microsoft Visual Basic для приложений окно.

2. Затем дважды щелкните Эта рабочая тетрадь слева Проекты под застройку панель, а затем скопируйте и вставьте приведенный ниже код VBA в пустой модуль.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Все еще в Microsoft Visual Basic для приложений окно, пожалуйста, нажмите Вставить > Модули, и вставьте следующий код в этот модуль.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. После вставки кодов нажмите Tools > РекомендацииИ Ссылки-VBAProject отображается диалоговое окно, а затем установите флажок Microsoft Visual Basic для расширяемости приложений 5.3 вариант в Доступные ссылки список, см. снимок экрана:

5. Затем нажмите OK чтобы выйти из диалогового окна, вы должны сохранить эту книгу как Excel Macro-Enabled Workbook формат, см. снимок экрана:

6. Наконец, перезапустите книгу, чтобы применить эффект кодов, и теперь, когда вы щелкаете правой кнопкой мыши ячейку, Запустить макрос опция вставляется в меню, вызываемое правой кнопкой мыши, и все макросы в вашей книге перечислены в подменю, как показано на следующем снимке экрана:

7. Затем вы можете запустить код, просто щелкнув его.