Как сохранить рабочий лист в виде файла PDF и отправить его по электронной почте в виде вложения через Outlook?

В некоторых случаях вам может потребоваться отправить рабочий лист в виде файла PDF через Outlook. Обычно вам нужно вручную сохранить рабочий лист как файл PDF, затем создать новое электронное письмо с этим файлом PDF в качестве вложения в Outlook и, наконец, отправить его. Это требует времени, чтобы сделать это вручную, шаг за шагом. В этой статье мы покажем вам, как быстро сохранить рабочий лист в виде файла PDF и автоматически отправить его в виде вложения через Outlook в Excel.

Сохраните рабочий лист как PDF-файл и отправьте его по электронной почте как вложение с кодом VBA.

Сохраните рабочий лист как PDF-файл и отправьте его по электронной почте как вложение с кодом VBA.

Вы можете запустить приведенный ниже код VBA, чтобы автоматически сохранить активный лист в виде файла PDF, а затем отправить его по электронной почте как вложение через Outlook. Пожалуйста, сделайте следующее.

1. Откройте рабочий лист, который вы сохраните в формате PDF и отправите, затем нажмите другой + F11 клавиши одновременно, чтобы открыть Microsoft Visual Basic для приложений окно.

2. в Microsoft Visual Basic для приложений окна, нажмите Вставить > Модули. Затем скопируйте и вставьте приведенный ниже код VBA в Code окно. Смотрите скриншот:

Код VBA: сохраните рабочий лист как файл PDF и отправьте его по электронной почте как вложение

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" + xSht.Name + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file 
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email 
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

3. нажмите F5 ключ для запуска кода. в Вставить диалоговом окне выберите папку для сохранения этого PDF-файла, а затем щелкните OK .

Заметки:

Статьи по теме:

• Как сохранить имя файла Excel с отметкой времени?
• Как использовать функцию «Сохранить как» для автоматической перезаписи существующего файла в Excel?
• Как сохранить, экспортировать несколько / все листы в отдельные CSV или текстовые файлы в Excel?
• Как отключить или запретить параметры «Сохранить и сохранить как» в Excel?
• Как отключить сохранение книги, но разрешить сохранение только как в Excel?