Как отслеживать изменения без общего доступа к книге?

Обычно, когда вы применяете функцию отслеживания изменений в Excel, книга одновременно становится общей, что может раздражать, поскольку некоторые функции Excel будут отключены. Как можно отслеживать изменения без предоставления общего доступа к книге? Здесь я порекомендую вам код VBA.

Отслеживание изменений без предоставления общего доступа к книге с помощью кода VBA

Преобразование текста в таблицу в Outlook

Прямого способа решить эту проблему нет, но вы можете использовать гибкий код VBA. Пожалуйста, следуйте этим шагам:

1. Щелкните правой кнопкой мыши по вкладке листа, где вы хотите отслеживать измененные ячейки, и выберите Вид Кода из контекстного меню. В открывшемся окне Microsoft Visual Basic for Applications скопируйте и вставьте следующий код в пустой Модуль:

Код VBA: Отслеживание изменений без предоставления общего доступа к книге:

Private Sub Worksheet_Change(ByVal Target As Range)
  'Updateby Extendoffice
    Const xRg As String = "A1:Z1000"
    Dim strOld As String
    Dim strNew As String
    Dim strCmt As String
    Dim xLen As Long
    With Target(1)
        If Intersect(.Cells, Range(xRg)) Is Nothing Then Exit Sub
        strNew = .Text
        Application.EnableEvents = False
        Application.Undo
        strOld = .Text
        .Value = strNew
        Application.EnableEvents = True
        strCmt = "Edit: " & Format$(Now, "dd Mmm YYYY hh:nn:ss") & " by " & _
        Application.UserName & Chr(10) & "Previous Text :- " & strOld
        If Target(1).Comment Is Nothing Then
            .AddComment
        Else
            xLen = Len(.Comment.Shape.TextFrame.Characters.Text)
        End If
        With .Comment.Shape.TextFrame
            .AutoSize = True
            .Characters(Start:=xLen + 1).Insert IIf(xLen, vbLf, "") & strCmt
        End With
    End With
End Sub

Примечание: В приведенном выше коде A1:Z1000 — это диапазон данных, за которым вы хотите отслеживать изменения.

2. Затем сохраните и закройте это окно кода. Теперь, когда вы изменяете значения в любых ячейках в пределах указанного диапазона, изменения будут отслеживаться без предоставления общего доступа к книге. См. скриншот: