Как сохранить и закрыть книгу после бездействия в течение определенного времени?

Иногда вы можете случайно закрыть книгу, когда заняты другими делами в течение длительного времени, что может привести к потере важных данных в книге. Существуют ли способы автоматически сохранить и закрыть книгу, если вы не использовали ее в течение определенного времени?

Автоматическое сохранение и закрытие книги после бездействия в течение определенного времени с помощью VBA

Автоматическое сохранение и закрытие книги после бездействия в течение определенного времени с помощью VBA

В Excel нет встроенной функции для решения этой проблемы, но я могу предложить макрос, который поможет вам сохранить и закрыть книгу после периода бездействия.

1. Откройте книгу, которую вы хотите автоматически сохранять и закрывать после определенного количества секунд бездействия, и нажмите клавиши Alt + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставить > Модуль, чтобы создать скрипт модуля, и вставьте следующий код в него. Смотрите скриншот:

Dim CloseTime As Date
Sub TimeSetting()
    CloseTime = Now + TimeValue("00:00:15")
    On Error Resume Next
    Application.OnTime EarliestTime:=CloseTime, _
      Procedure:="SavedAndClose", Schedule:=True
End Sub
Sub TimeStop()
    On Error Resume Next
    Application.OnTime EarliestTime:=CloseTime, _
      Procedure:="SavedAndClose", Schedule:=False
 End Sub
Sub SavedAndClose()
    ActiveWorkbook.Close Savechanges:=True
End Sub

3. Затем в панели Обозреватель проектов дважды щелкните по ЭтотWorkbook и вставьте следующий код в соседний скрипт. Смотрите скриншот:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Call TimeStop
End Sub

Private Sub Workbook_Open()
    Call TimeSetting
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
   Call TimeStop
   Call TimeSetting
End Sub

4. Перейдите к модулю, который вы вставили на шаге 2, и дважды щелкните его, затем нажмите F5 , чтобы запустить код. Смотрите скриншот:

5. Через 15 секунд появится диалоговое окно с напоминанием о необходимости сохранить книгу, и нажмите Да , чтобы сохранить и закрыть книгу.

Советы:

(1) В первом коде вы можете изменить время бездействия на другое в этой строке: Now + TimeValue("00:00:15")

(2) Если вы никогда раньше не сохраняли книгу, то диалоговое окно Сохранить как появится первым и попросит вас сохранить ее.