Как сделать все конкретные слова в диапазоне ячеек жирными?

В Excel функция «Поиск и Замена» может помочь нам найти любой конкретный текст и применить к целым ячейкам форматирование, например, сделать их жирными или другое. Но пробовали ли вы когда-нибудь сделать жирным только определенный текст внутри ячеек, а не всю ячейку целиком, как показано на скриншоте ниже:

Выделить жирным все конкретные слова в диапазоне ячеек с помощью кода VBA

Выделить жирным все конкретные слова в диапазоне ячеек с помощью кода VBA

Следующий код VBA может помочь вам выделить жирным только определенный текст в содержимом ячейки. Пожалуйста, выполните следующие действия:

1. Нажмите и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставить > Модуль и вставьте следующий код в окно Модуля.

Код VBA: Выделение жирным конкретного текста в диапазоне ячеек

Sub FindAndBold()
'Updateby Extendoffice 20160711
    Dim xFind As String
    Dim xCell As Range
    Dim xTxtRg As Range
    Dim xCount As Long
    Dim xLen As Integer
    Dim xStart As Integer
    Dim xRg As Range
    Dim xTxt As String
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Please select data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    On Error Resume Next
    Set xTxtRg = Application.Intersect(xRg.SpecialCells(xlCellTypeConstants, xlTextValues), xRg)
    If xTxtRg Is Nothing Then
        MsgBox "There are no cells with text"
        Exit Sub
    End If
    xFind = Trim(Application.InputBox("What do you want to BOLD?", "Kutools for Excel", , , , , , 2))
    If xFind = "" Then
        MsgBox "No text was listed", vbInformation, "Kutools for Excel"
        Exit Sub
    End If
    xLen = Len(xFind)
    For Each xCell In xTxtRg
        xStart = InStr(xCell.Value, xFind)
        Do While xStart > 0
            xCell.Characters(xStart, xLen).Font.Bold = True
            xCount = xCount + 1
            xStart = InStr(xStart + xLen, xCell.Value, xFind)
        Loop
    Next
    If xCount > 0 Then
        MsgBox "number of " & CStr(xCount) & " text be bolded!", vbInformation, "Kutools for Excel"
    Else
        MsgBox "Not find the specific text!", vbInformation, "Kutools for Excel"
    End If
End Sub

3. Затем нажмите клавишу F5 для запуска этого кода, и появится диалоговое окно, которое напомнит вам выбрать диапазон данных, который вы хотите выделить жирным шрифтом, см. скриншот:

4. После этого нажмите OK, появится еще одно окно, которое предложит вам ввести конкретный текст, который нужно выделить жирным только в ячейках, см. скриншот:

5. После ввода текста нажмите кнопку OK, и весь указанный вами текст будет выделен жирным шрифтом в выбранном диапазоне, см. скриншот: