Как отправить электронное письмо нескольким получателям из списка в Excel через Outlook?

Если у вас есть несколько адресов электронной почты в столбце рабочего листа, и вы хотите отправить письмо этому списку получателей непосредственно из Excel, не открывая Outlook. В этой статье я расскажу о том, как отправить электронное письмо нескольким получателям одновременно из Excel.

Отправка электронного письма нескольким получателям из Excel с помощью кода VBA

Отправка электронного письма нескольким получателям с текущей книгой в качестве вложения с использованием кода VBA

Отправка электронного письма нескольким получателям из Excel с помощью кода VBA

Вы можете использовать код VBA для отправки сообщения нескольким получателям одновременно, выполните следующие действия:

1. Нажмите и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставить > Модуль и вставьте следующий код в окно Модуля.

Код VBA: Отправка электронного письма нескольким получателям

Sub sendmultiple()
'updateby Extendoffice
    Dim xOTApp As Object
    Dim xMItem As Object
    Dim xCell As Range
    Dim xRg As Range
    Dim xEmailAddr As String
    Dim xTxt As String
    On Error Resume Next
    xTxt = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Please select the addresses list:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Set xOTApp = CreateObject("Outlook.Application")
    For Each xCell In xRg
        If xCell.Value Like "*@*" Then
            If xEmailAddr = "" Then
                xEmailAddr = xCell.Value
            Else
                xEmailAddr = xEmailAddr & ";" & xCell.Value
            End If
        End If
    Next
    Set xMItem = xOTApp.CreateItem(0)
    With xMItem
        .To = xEmailAddr
        .Display
    End With
End Sub

3. Затем нажмите клавишу F5 для выполнения этого кода, появится диалоговое окно с напоминанием выбрать список адресов, см. скриншот:

4. Затем нажмите ОК, и отобразится окно Сообщения Outlook, вы увидите, что все выбранные адреса электронной почты добавлены в поле Кому, после чего вы можете ввести тему и составить ваше сообщение, см. скриншот:

5. После завершения составления сообщения нажмите кнопку Отправить, и это сообщение будет отправлено этим получателям из списка вашего рабочего листа.

Отправка электронного письма нескольким получателям с текущей книгой в качестве вложения с использованием кода VBA

Если вам нужно отправить сообщение нескольким получателям с текущей книгой в качестве вложения, вы можете применить следующий код VBA.

1. Нажмите и удерживайте клавиши ALT + F11, чтобы открыть окно Microsoft Visual Basic for Applications.

2. Нажмите Вставить > Модуль и вставьте следующий код в окно Модуля.

Код VBA: Отправка электронного письма нескольким получателям с текущей книгой в качестве вложения

Sub EmailAttachmentRecipients()
'updateby Extendoffice
    Dim xOutlook As Object
    Dim xMailItem As Object
    Dim xRg As Range
    Dim xCell As Range
    Dim xEmailAddr As String
    Dim xTxt As String
    On Error Resume Next
    xTxt = ActiveWindow.RangeSelection.Address
    Set xRg = Application.InputBox("Please select the arresses list:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Set xOutlook = CreateObject("Outlook.Application")
    Set xMailItem = xOutlook.CreateItem(0)
    For Each xCell In xRg
        If xCell.Value Like "*@*" Then
            If xEmailAddr = "" Then
                xEmailAddr = xCell.Value
            Else
                xEmailAddr = xEmailAddr & ";" & xCell.Value
            End If
        End If
    Next
    With xMailItem
        .To = xEmailAddr
        .CC = ""
        .Subject = ""
        .Body = ""
        .Attachments.Add ActiveWorkbook.FullName
        .Display
    End With
    Set xOutlook = Nothing
    Set xMailItem = Nothing
End Sub

3. После вставки кода нажмите клавишу F5 для запуска этого кода, появится диалоговое окно с напоминанием выбрать адреса, которым вы хотите отправить сообщение, см. скриншот:

4. Затем нажмите кнопку ОК, и отобразится окно Сообщения Outlook, все адреса электронной почты будут добавлены в поле Кому, а также ваша текущая книга будет вставлена как вложение, после чего вы можете ввести тему и составить ваше сообщение, см. скриншот:

5. Затем нажмите кнопку Отправить, чтобы отправить это сообщение списку получателей с текущей книгой в качестве вложения.

Связанная статья:

Как отправить персонализированные массовые письма из списка в Excel через Outlook?